Moyenne.si.ensemble avec valeurs issues de macro
Bonjour,
Ayant déjà reçu une aide efficace pour ce même fichier, je refais appel à votre précieux savoir.
Je récapitule : Il s'agit d'un fichier (que j'ai ici rendu anonyme au niveau des données) qui sert à rendre compte des consommations de différents véhicules utilisés dans une entreprise.
Je suis maintenant dans la feuille "Rapport mensuel", qui doit permettre d'imprimer une page reprenant les données par véhicule pour un mois défini (En B1). Dans la colonne "Moyenne (Reel. Consommée) ", je cherche à faire la moyenne des valeurs présente dans la colonne O de la page DATA , pour la plaque correspondante (en colonne B), et pour les date situées entre le premier et le dernier jour du mois sélectionné au dessus (Dates calculées respectivement en F1 et H1, feuille "Rapport mensuel).
Évidemment, la feuille "Data" qui reprend la source des données est amenée à s'étoffer au fur et à mesure, et les formules se tireront automatiquement.
J'ai bien essayé avec une formule Moyenne.si.ens, mais rien n'y fait, elle me ramène systématiquement la valeur DIV#0
Est-ce lié au fait que certaines valeurs sont indirectement issues de fonctions macro ?
Mon fichier anonyme est joint à ce message.
D'avance merci pour votre aide à tous, n'hésitez pas si vous voulez plus de précisions :-)
VVVVV
Bonsoir,
Utiliser plutôt
=SOMMEPROD((DATA[Colonne1]>=$F$1)*(DATA[Colonne1]<=$H$1)*(DATA[Plaque Véhicule]=[@Plaque])*(DATA[Moyenne de consommation]))à la place du somme.si.ens et remplacer les "" par un 0 dans la formule de la colonne O de l'onglet DATA.
Cordialement.
Bonjour à tous
=SOMMEPROD((DATA[Colonne1]>=$F$1)*(DATA[Colonne1]<=$H$1)*(DATA[Plaque Véhicule]=[@Plaque])*(DATA[Moyenne de consommation]))à la place du somme.si.ens et remplacer les "" par un 0 dans la formule de la colonne O de l'onglet DATA.
Euh c'était MOYENNE.SI.ENS donc il faudrait compléter la formule
Cependant une moyenne de moyennes est mathématiquement fausse
Il faudrait faire le calcul sur la somme des consommations et la somme des Kms donc 2 SOMME.SI.ENS ou 2 SOMMEPROD
Hello 78chris,
Euh c'était MOYENNE.SI.ENS donc il faudrait compléter la formule
Au temps pour moi. Voulu mettre la charrue avant les bœufs.
Cordialement
Bonjour Vincent
Sur 2 forums différents en 3 minutes d'écart ,faut le faire...
Bonjour,
@Zebulon2, merci beaucoup , ca semble marcher, je vais quand même inspecter les valeurs incohérentes pour voir si elles sont normales.
@Joco7915, J'augmente mes chances de réponses parce qu'elles sont toutes très intéressantes à chaque fois et j'apprends plein de choses :-)
@78chris , "Cependant une moyenne de moyennes est mathématiquement fausse". Tu m'intéresses mais je suis pas sûre de comprendre. Peux tu développer ?
@tous, je ne pourrai pas répondre avant une semaine, ne me prenez donc pas pour un impoli si vous restez dans le vent pendant cette période :-)
Encore merci à tous !
VVVVVV
re,
Pour tenir compte de la remarque de 78chris, un autre calcul, mais il semble que tes fonctions ne renvoient pas toujours un résultat.
=SIERREUR((SOMMEPROD((DATA[Colonne1]>=$F$1)*(DATA[Colonne1]<=$H$1)*(DATA[Plaque Véhicule]=[@Plaque])*(DATA[Dernier plein réalisé]))/(MAX.SI.ENS(DATA[Dernier relevé kilométrique];DATA[Plaque Véhicule];[@Plaque];DATA[Colonne1];">="&$F$1;DATA[Colonne1];"<="&$H$1)-MIN.SI.ENS(DATA[Kilométrage véhicule];DATA[Plaque Véhicule];[@Plaque];DATA[Colonne1];">="&$F$1;DATA[Colonne1];"<="&$H$1)))*100;"")Cordialement
RE
Tu prends un village de déserté où ne restent que 50 papies mamies de 75 à 95 ans et tu fait la moyenne d'âge . Disons qu'on obtient 82
Tu prends et une ville de Seine Saint Denis généralement très peuplée (disons 100 000 habitants) etavec beaucoup de jeunes. On obtient par exemple 40 ans de moyenne.
Crois-tu que la moyenne globale des 2 villes soit de 61 ans pour 100 050 habitants ?
Rebonjour à tous,
@78chris Effectivement très clair et juste, merci. Je me dis cependant que dans mon cas, la moyenne n'est calculée systématiquement que pour un véhicule et non sur la globalité, j'ai donc l'impression qu'elle ne doit pas être loin de la vérité. Mais je reconnais bien que mathématiquement, c'est assez bancale.
Je vais donc plutôt tenter de calculer directement sur base des colonnes sources (KM et Litre) du coup
@Zebulon2, SI tu parles des premières lignes, cela se justifie par le fait qu'il s'agit des premières données collectées pour le véhicule, il est donc impossible de remonter plus en arrière (et donc de calculer une moyenne (et donc une moyenne de moyenne (qui serait mathématiquement fausse en plus))). :-)
Merci, je vais tester cela du coup.
Bonjour à tous :-)
@Zebulon2, Après avoir analyser ta formule, j'ai plusieurs remarques/questions.
D'abord, n'ayant qu'Excel 2013, je dois adapter les formules MIN & MAX.SI.ENS en MAX(SI(...)*(...)) matriciel, mais jusque là ok, j'y arrive
Mais si je traduis ton calcul et que je ne dis pas de bêtise, tu fais ceci :
(Somme des précédents pleins réalisés sur chacun des passages à la pompe du mois choisi, pour une plaque donnée)(L) x100(Le + grand kilométrage des passage x-1 sur le mois choisi/plaque) - (Le + petit kilométrage du passage x sur le mois choisi/plaque)
Alors j'ai du mal avec ton dénominateur et la manière de calculer les kilomètres parcourus sur un mois. Pour moi il est plus logique de calculer comme ca :
(Le + grand kilométrage des passage x sur le mois choisi/plaque) - (Le + petit kilométrage du passage x-1 sur le mois choisi/plaque)
Ce qui me donne au final la formule :
=SIERREUR(SOMMEPROD((Tableau29[Colonne1]>=$F$1)*(Tableau29[Colonne1]<=$H$1)*(Tableau29[Plaque Véhicule]='Rapport mensuel'!$B3)*(Tableau29[Dernier plein réalisé]))/(MAX(SI((Tableau29[Plaque Véhicule]='Rapport mensuel'!B3)*(Tableau29[Colonne1]>='Rapport mensuel'!$F$1)*(Tableau29[Colonne1]<='Rapport mensuel'!$H$1);Tableau29[Kilométrage véhicule];""))-MIN(SI((Tableau29[Plaque Véhicule]='Rapport mensuel'!$B3)*(Tableau29[Colonne1]>='Rapport mensuel'!$F$1)*(Tableau29[Colonne1]<='Rapport mensuel'!$H$1);Tableau29[Dernier relevé kilométrique];"")))*100;"")Avec des résultats plus cohérents je dois dire... êtes vous ok avec ça ?
(Ne faites pas attention a ma référence tableau29, elle a un nom différent dans mon fichier original)
Au plaisir d'avoir votre avis, merci d'avance
VVVVV
Bonsoir,
Oui, cela semble juste.
Cordialement.