Somme des valeurs numéraires
Bonjour à tous,
Dans une cellule je peux avoir plusieurs dates et cotisations.
Je souhaiterais avoir la somme des cotisations comme ceci :
Merci de vos réponses
Bonjour.
Juste sur le pif, pourquoi ne pas mettre une colonne des montants séparément ?
Bonjour,
d'où l'intérêt de ne pas fusionner les cellules ou mettre plusieurs infos dans une seule cellule...
Un peu bebête cette façon de faire ! Manque d'expérience je présume ?
P.
Bonjour
Un exemple avec une macro
Mettre le sujet en résolu si cela te convient
Bonjour à tous,
Si j'interprète "366" comme Excel 365, essaie :
=REDUCE(0;FRACTIONNER.TEXTE(TabCotis[@Cotis];CAR(10);;1);LAMBDA(x;y;INDEX(FRACTIONNER.TEXTE(y;" - ");2)+x))en D4, à recopier vers le bas.
Daniel
Bonjour à tous !
Pour le "fun" et avec M365 :
Option 1 :
=SOMME(REGEX.EXTRAIRE(B4;" \d{,2} ";1)*1)Formule à recopier vers le bas (sauf intégration dans un tableau structuré)
Option 2 :
=MAP(B4:B11;LAMBDA(x;SOMME(REGEX.EXTRAIRE(x;" \d{,2} ";1)*1)))Formule unique dynamique (non-intégrée dans un tableau structuré)
Bonjour à tous,
Une autre proposition pour Excel 365 prenant en compte tous les nombres entourés d'un espace :
=SOMME(--REGEX.EXTRAIRE(TabCotis[@Cotis];" \d+ ";1))Bonjour à tous,
@ ceux qui critiquent : c'est justement parce que j'ai cette disposition difficile que je viens chercher de l'aide, sinon avec mon faible niveau je sais faire ! Et apparemment on est dans le même cas, j'attends vos propositions.
@ ceux ceux qui tentent une solution : merci à eux, mais j'ai omis de préciser explicitement que j'évolue dans un environnement sans vba et multi plateformes de Excel 2021 à 365. Pouvez-vous adapter vos solutions ?
Bonjour,
Avec Windows uniquement :
=SOMME(CNUM(GAUCHE(DROITE(FILTRE.XML("<M><R>"&SUBSTITUE(TabCotis[@Cotis];CAR(10);"</R><R>")&"</R></M>";"//R");4);2)))Daniel
... Sinon, quel que soit le montant de la cotisation :
=SOMME(CNUM(STXT(FILTRE.XML("<M><R>"&SUBSTITUE(TabCotis[@Cotis];CAR(10);"</R><R>")&"</R></M>";"//R");12;CHERCHE("€";FILTRE.XML("<M><R>"&SUBSTITUE(TabCotis[@Cotis];CAR(10);"</R><R>")&"</R></M>";"//R"))-12)))Daniel
... La même, raccourcie (pour Excel 2021 et versions postérieures) :
=LET(tbl;FILTRE.XML("<M><R>"&SUBSTITUE(TabCotis[@Cotis];CAR(10);"</R><R>")&"</R></M>";"//R");SOMME(CNUM(STXT(tbl;12;CHERCHE("€";tbl)-12))))Bonjour,
Allez une de plus puisque le format de la colonne semble toujours de 15 caractères :
=(STXT(TabCotis[@Cotis];12;2))*1
Bonjour à tous,
@ DanielC, merci beaucoup, tes formules fonctionnent très bien sur l'exemple, mais j'ai des cas ou cela ne marche pas comme ici :
20/01/26 toto - 12 €
20/01/26 tata - 345 €
(attendu 357)
@ Xmenpl, non ce n'est pas le résultat souhaité
Bonjour,
@ DanielC, merci beaucoup, tes formules fonctionnent très bien sur l'exemple, mais j'ai des cas ou cela ne marche pas comme ici :
Quelle est la solution que vous utilisez ? Il en a posté plusieurs ..
Celle qu'il a proposé ici fonctionne --> https://forum.excel-pratique.com/s/goto/1269302 si vous remplacez le chiffre 4 par 5 et le chiffre 2 par 3
NB : pensez à corriger la version excel dans votre profil de compte. Remplacez 366 par 365
Crdlt
Bonjour à tous,
S'il peut y avoir un nom après la date :
=LET(tbl;FILTRE.XML("<M><R>"&SUBSTITUE(TabCotis[@Cotis];CAR(10);"</R><R>")&"</R></M>";"//R");SOMME(CNUM(STXT(tbl;CHERCHE(" - ";tbl)+3;CHERCHE("€";tbl)-12))))Daniel
Bonjour à tous,
@Dan Ok mais pas pour des valeurs supérieures à 1000,
@DanielC : parfait
En conclusion je prends la version de BeGood pour Excel 365 et la dernière de DanielC pour Excel 2021
(@JExcel2fr je t'ai mis un -1 aussi)
re
@Dan Ok mais pas pour des valeurs supérieures à 1000,
Ok mais il fallait le savoir car vous ne l'avez pas précisé.
Au début vous mentionnez 2 chiffres, puis 3 chiffres....
Mais bon vous avez votre solution avec DanielC & BGood. C'est le principal
@JExcel2fr je t'ai mis un -1 aussi)
Où je me trompe mais je ne vois pas de post de Jexcel2fr...
Cordialement