Fonction Filtre

Bonjour à tous

J'ai actuellement une fonction filtre en place comme suit et qui fonctionne:

=FILTRE(Tableau3[[Nom]:[Type de suvis]];Tableau3[BDMGIS]="Oui";0)

Je souhaiterai modifier la colonne de recherche Tableau3[BDMGIS] en fonction d'un menu déroulant en B2

Comment dois je réécrire cet argument ?

Bonjour,

Tu peux utiliser EQUIVX + CHOISIRCOLS pour trouver le numéro de colonne (EQUIVX) correspondant à ton menu déroulant, et CHOISIRCOLS pour indiquer à ton filtre de s'effectuer sur cette colonne.

Si tu veux une application concrète, merci de joindre un fichier à ton message.

Bonjour,

Essaie :

=FILTRE(Tableau3[[Nom]:[Type de suivis]];INDIRECT("Tableau3[["&B2&"]]")="Oui";0)

Daniel

Après quelques essaie je n'arrive pas implémenter ta solution

Le fichier déroulant indiquant la bonne colonne à sélectionner est en H2

Le tableau est sur la feuille suivi

Voici mon fichier

Bonjour,
Essaie ainsi :

=FILTRE(T_Suivi[[Nom]:[Type de suvis]]; INDIRECT("T_Suivi[" & H2 & "]") = "Oui"; 0)

Ou bien, par rapport au fichier joint

=FILTRE(Tableau33[[Nom]:[Type de suvis]];CHOISIRCOLS(Tableau33;EQUIVX(H2;Tableau33[#En-têtes]))="Oui";0)

Bonjour à tous !

Une petite dernière ?

=FILTRE(Tableau33[[Nom]:[Type de suvis]];INDEX(Tableau33;;EQUIVX(H2;Tableau33[#En-têtes]))="Oui";0)

En adaptant à ton classeur :

=FILTRE(Tableau33[[Nom]:[Type de suvis]];INDIRECT("Tableau33["&H2&"]")="Oui";0)

Daniel

Merci à vous

Çà fonctionne parfaitement

Re,
Et encore une autre :

=LET(
r; Tableau33;
h; Tableau33[#En-têtes];
c; FILTRE(r; RECHERCHEX(H2; h; r)="oui");
CHOISIRCOLS(c;1;2)
)

Content que les solutions fonctionnent, mais n'oubliez pas de clôturer le fil. Bonne journée.