Recherche de valeurs dans colonne et fonction SI
J'ai un problème pour réaliser et finaliser mon application Excel.
- En colonne A, j'ai une liste de prénom de A1 à A4 (Personnes de TOULOUSE)
- En colonne B, j'ai une liste de prénom de B1 à B3 (personnes de BORDEAUX)
- En colonne C, j'ai une liste de prénom de C1 à C3 (personnes de PARIS)
- En colonne E, j'ai une extraction de prénoms qui sont présents soit dans la colonne A ou B ou C
Je voudrais mettre une formule dans toutes les cellules de la colonne D pour que en fonction du prénom en colonne E, il s'inscrive automatiquement TOULOUSE ou BORDEAUX ou PARIS
J'ai tout essayé mais je ne m'en sort pas
Merci de votre aide
Bonjour,
Les villes se trouvent dans quelle colonne ?
A te lire
Dan
je n'avais pas prévue de lister les villes dans une colonne. Je pensais qu'il était possible d'intégrer dans une formule que si la valeur de la cellule en colonne E était comprise dans la colonne A alors "TOULOUSE" ou si la valeur était comprise dans la colonne B alors "BORDEAUX ..etc
Mais si pour faciliter la résolution de mon problème il faut créer une colonne sup, c'est sans problème. De toute façon, j'avais envisagé de masquer ces colonnes qui ne servent que pour les formules.
Merci de ton aide
Bonjour,
Le plus simple est de mettre les noms des villes en en-tête des colonnes (donc A1, B1 et C1)
Mets un petit exemple en pièce jointe, ce sera plus rapide.
Comment te mettre un fichier excel en exemple sur ce forum ?
re,
Suis la rocédure en cliquant en haut de cette page sur "joindre un fichier"
A te lire
Dan
Re,
Une solution parmi beaucoup d'autres :
En D1 : =CHOISIR(NB.SI(A$1:A$10;E1)*1+NB.SI(B$1:B$10;E1)*2+NB.SI(C$1:C$10;E1)*3;"TOULOUSE";"BORDEAUX";"PARIS")
formule à étirer vers le bas.
Les plages 1:10 sont à adapter suivant besoins.
Salut pinpin,
tu peux essayer avec cette formule en D1 (à recopier vers le bas) :
=CHOISIR((NB.SI($A$1:$A$50;E1)*1+NB.SI($B$1:$B$50;E1)*2+NB.SI($C$1:$C$50;E1)*2)+1;"Inconnu";"Toulouse";"Bordeaux";"Paris")
Attention aux doublons. S'il s'agit réellement de traiter des prénoms, il est fort à parier que tu vas te retrouver à un moment ou un autre avec des prénoms identiques dans plusieurs villes.
@+
Edit : salut André : je jure que j'ai pas triché sur toi !!!
@+
re,
une autre solution avec une formule matricielle :
en D1 :
=INDEX({"Toulouse"\"Bordeaux"\"Paris"};MIN(SI($A$1:$C$49=E1;COLONNE($A$1:$C$1))))
Formule à valider par CTRL + MAJ + ENTREE
@+
Salut thibo,
Je veux bien croire que tu n'as pas triché, d'ailleurs ce n'est pas la première fois que cela nous arrive.
Bien vu pour l'inconnu (absence) et la remarque concernant d'éventuels doublons, mais le deuxième *2 dans ta formule aurrait tout avantage à être remplacé par un *3
Et pourquoi pas la formule suivante :
=CHOISIR(((NB.SI(A$1:A$10;E1)+NB.SI(B$1:B$10;E1)*2+NB.SI(C$1:C$10;E1)*3)*NB.SI(A$1:C$10;E1)=1)+1;"Inconnu ou Doublon";"TOULOUSE";"BORDEAUX";"PARIS")
Salut André,
De la confrontation des neurones découle souvent de lumineuses formules.
le *2 à remplacer par un *3 provenait d'un petit souci de Copier/Coller.
J'ai testé ta formule : j'y ai ajouté 2 parenthèses de part et d'autre de :
(NB.SI(A$1:C$10;E1)=1)
paenthèses qui me paraissent nécessaires.
Je pense que notre ami est ainsi gâté en ayant une panoplie de réponses à sa disposition.
Bon Week-end à toi et au Forum
@+
Effectivement, je venais aussi de remarquer qu'il y avait quelque chose qui n'allait pas.
J'arrive évidemment à la même conclusion que toi, comme quoi il faut toujours tester !
=CHOISIR(((NB.SI(A$1:A$10;E1)+NB.SI(B$1:B$10;E1)*2+NB.SI(C$1:C$10;E1)*3)*(NB.SI(A$1:C$10;E1)=1))+1;"Inconnu ou Doublon";"TOULOUSE";"BORDEAUX";"PARIS")
J'ai mis ta formule :
=CHOISIR(NB.SI(A$1:A$10;E1)*1+NB.SI(B$1:B$10;E1)*2+NB.SI(C$1:C$10;E1)*3;"TOULOUSE";"BORDEAUX";"PARIS")
Celà marche super !!!
Je ne sais comment te remercier de ne plus avoir ces longues soirées de migraine à essayer de trouver une formule qui fonctionne.
Encore merci pour tout.