RechercheV ou RechercheX avec plusieurs critères ?

Bonjour,
J'ai plusieurs colonnes, telles que "longueur", "largeur", "épaisseur" dans ma base de données. Je voudrais chercher ces données dans la base de données et ressortir une autre information associée (par exemple le prix correspondant pour la fourniture avec ces dimensions) sur une autre feuille.
J'ai essayé plusieurs méthodes, mais sans succès jusqu'à maintenant, notamment avec RechercheX...

J'ai essayé ceci sans succès :

=XLOOKUP(1, (Test!F:F=B3)*(Test!G:G=B4)*(Test!H:H=B5), Test!I:I)

Dans un second temps, j'aimerais, si possible, sortir tous les prix correspondant à ces mêmes dimensions (s'il y en a plusieurs qui correspondent à ces dimensions).

Merci d'avance !

Bonjour,

Et un Query ?

=Query(Test!F:I;"select F,G,H,I where F = '"&B3&"' and G = '"&B4&"' and H = '"&B5&"'")

Bonjour, cela me sort la première ligne des colonnes F,G,H,I (c'est-à-dire les titres des colonnes "Longueur", "Largeur", "Epaisseur" etc). Je souhaiterais seulement avoir la valeur du prix correspondant aux dimensions recherchés.
Ma base de données est construite telle que :

Bonjour Kai,

Je n'ai pas testé, mais la proposition de Pierre a l'air correcte...

As-tu bien mis la formule QUERY dans un autre onglet que Test?

As-tu bien mis dans ce nouvel onglet en B3, B4 , B5 les longueurs, largeurs, épaisseurs que tu souhaites rechercher?

Cordialement,

Fil.

Bonjour Filoche,

Oui, c'est bien ce que j'ai fait...

Je viens de faire le test, il faut retirer les '

et ça fonctionne bel et bien, les en-tête s'affichent systématiquement (pour les masquer, il faut ajouter ;0 à la fin du query.

=Query(Test!F:I;"select F,G,H,I where F = "&B3&" and G = "&B4&" and H = "&B5&"")

Bonjour,

Il s'agit d'un problème de format, je n'ai pas testé mais en formattant les colonnes F, G et H en texte, le problème devrait être résolu.

De plus si dans votre feuille de recherche vous noter manuellement les dimensions (B3, B4, B5) pour obtenir le ou les prix associés pourriez ne faire apparaître que les prix dans la formule

=query(Test!$F:$I;"SELECT I WHERE F = '"&$B$3&"' AND G = '"&$B$4&"' AND H = '"&$B$5&"' ";0)

J'ai testé depuis un autre ordinateur vos suggestions, et la formule de PierreLepinay fonctionne. Cependant, je ne souhaiterais afficher que le prix, et la formule affiche tous les paramètres. En la modifiant, pour ne la faire apparaître que la valeur de la colonne I telle que l'a écrite Fred_Bzh, la formule ne fonctionne plus... Sauriez-vous pourquoi ?

Merci d'avance !

Voici le lien du doc google sheet, si vous souhaitez voir ce que j'obtiens :
https://docs.google.com/spreadsheets/d/1GAg0yxsxSxXEs9pVeKVLGdCkFIdx3aoELYB3S0coFz4/edit?usp=sharing

Bonjour

Comme l'a dit Pierre, il faut enlever les '

=QUERY(Test!$F:$I;"SELECT I WHERE F = "&$B$3&" AND G = "&$B$4&" AND H = "&$B$5&" ";0)

et si vous souhaitez avoir les prix afficher horizontalement :

=TRANSPOSE(QUERY(Test!$F:$I;"SELECT I WHERE F = "&$B$3&" AND G = "&$B$4&" AND H = "&$B$5&" ";0))

Ces 2 formules affichent tous les prix pour les dimensions recherchées.

Merci beaucoup à vous !

=QUERY(Test!$A:$O;"SELECT J WHERE F = "&$B$3&" AND G = "&$B$4&" AND H = "&$B$5&" AND B="&$B$1&" ";0)

=QUERY(Test!$A:$O;"SELECT J WHERE F = "&$B$3&" AND G = "&$B$4&" AND H = "&$B$5&" AND B='Table' ";0)

La ligne fonctionne bien, mais quand j'écrit la première ligne (avec la case B1 contenant "Table"), cela ne fonctionne plus...

Merci d'avance !

Bonjour,

Ça devrait pourtant fonctionner, pouvez-vous partager un fichier ?

=QUERY(Test!$A:$O;"SELECT J WHERE F = "&$B$3&" AND G = "&$B$4&" AND H = "&$B$5&" AND B= '"&$B$1&"' ";0)

Merci !