Dernière cellule vide à partir d'un certain rang

Bonjour à tous,

Comment je peux saisir le contenu d'une textbox dans la dernière cellule vide d'une feuille à partir de la ligne 15 de la colonne N ?

Ce sujet est apparu déjà plusieurs fois pour les tableaux commençant à partir de la ligne 1 mais pas à partir d'une ligne quelconque.

Un grand merci d'avance pour votre aide.

Bonjour

Un exemple de ton fichier pourrait nous aider à y voir clair

Crdlt

Ci dessous un exemple de ce que je souhaite car mon fichier est confidentiel :

Je souhaite que lorsque je clique sur valider, le contenu de ma textbox s'affiche dans mon cadre rouge. Et a chaque fois que je clique sur Valider que le contenu se mette en dessous de l'ajout précédent.

Quelqu'un aurait une solution ?

bonjour,

à ajouter dans Userform1

Private Sub CommandButton1_Click()
     With TextBox1
          If Len(.Value) > 0 Then
               With Sheets("Feuil1")
                    Set c = .Range("N" & Rows.Count).End(xlUp).Offset(1)
                    If c.Row < 15 Then Set c = .Range("N15")
               End With
               c.Value = .Value
               .Value = ""
          End If
     End With
End Sub

Bonjour à tous,

Une variante....à tester...

Private Sub CommandButton1_Click()
 With Sheets("Feuil1")
  If Me.TextBox1 = "" Then Exit Sub
   dl = IIf(.Range("N" & Rows.Count).End(xlUp).Row + 1 < 15, 15, .Range("N" & Rows.Count).End(xlUp).Row + 1)
   .Cells(dl, "N") = Me.TextBox1
 End With
End Sub

Cordialement,

@xorsankukai,

si c'est pour simplifier, encore une variante

dl = Application.Max(.Range("N" & Rows.Count).End(xlUp).Row + 1, 15)

Re,

si c'est pour simplifier, encore une variante

dl = Application.Max(.Range("N" & Rows.Count).End(xlUp).Row + 1, 15)

Merci BsAlv, je ne connaissais pas cette méthode,

A bientôt sur le forum,