Afficher valeur dernière cellule non vide d'une colone
Bonjour à toutes et tous,
Après de moults recherches, je vous appelle à l'aide. Voici mon dilemme:
J'ai un tableau avec une plage de donnée (H3:H14) et je souhaiterais obtenir dans la cellule H15, la valeur de la dernière cellule non vide de la colone (H3:H15), soit dans le cas précis la valeur 13,30. Davance merci pour votre aide.
Bonjour,
Fais un essai avec cette formule :
=RECHERCHE(9^9;H3:H14)Je te laisse tester
@+
bonsoir
tu peux tester cela aussi:
=DECALER(H3;EQUIV(9^9;H3:H14;1)-1;;)ou
=INDEX(H3:H14;EQUIV(9^9;H3:H14;1))Eh bien merci pour toutes vos formules qui fonctionnent très bien et aussi pour votre rapidité de réponse. Merci sincèrement !
Bonsoir à tous et joyeuses fêtes,
Je viens de tester ces formules. Elles ne fonctionnent pas pour du texte. Cela est surement du au nombre 9^9.
Ainsi, est-ce possible d'obtenir la dernière cellule saisie que ce soit du texte ou non ?.
Merci à l'avance.
bonsoir
Remplace 9^9 par "zz", pour rechercher des valeurs textes.
valeur texte ou nombre
=INDEX(h3:h14;NBVAL(h3:A14))
=DECALER(h3;NBVAL(h3:h14)-1;;)mais si tu a des cellules vides dans les données ça ne fonctionne pas,
Bonsoir,
Effectivement ces formules sont pour des données numériques.
Pour du texte, remplaces 9^9 par "zzzz"
Si tu as à la fois du texte et des nombres, utilises celle-ci :
=INDIRECT(ADRESSE(MAX((H3:H14<>"")*LIGNE(H3:H14));COLONNE(H3:H14)))matricielle, à valider par ctrl+maj+entrée.
A+
Comme d'habitude, la richesse d'Excel permet de proposer plusieurs solutions :
=INDEX(H3:H14;SOMME(SI(H3:H14<>"";1;0)))
sous forme matricielle, à valider par ctrl+maj+entrée.
C'est applicable quel que soit le contenu de la plage H3 à H14 texte, valeurs, formules), à partir du moment où le contenu est différent de "".
J'ai recopié la formule de H3 jusqu'en H14 en désactivant l'erreur si les colonnes C à G sont vides.
Voir fichier joint.
Je pense qu'une autre solution serait de tester la plage B3:B14 qui est nécessairement remplie si les colonnes Cà H sont remplies.
re
dans la série
on peut mettre cela aussi:
=DECALER(h3;SI(EQUIV(9^9;$h3:$h14;1)<EQUIV("zzz";$h3:$h14;1);EQUIV("zzz";$h3:$h14;1);EQUIV(9^9;$h3:$h14;1))-1;;)Bonsoir à toutes et tous,
Merci à CB60, OOoiste et Lomanic.
J'avais en effet lu qu'avec "zz" le calcul était possible. Cependant je viens d'apprendre qu'il ne devait pas y avoir de cellules vides...
Je vais ainsi travailler avec vos formules et la plage $H3:$H9.
Bonne soirée à tous et encore MERCI.
bonsoir
SI SI portable tu peux utiliser une plage avec des cellules vides, texte ou numerique en adaptant la derniere formule.
Bonjour à tous,
En effet, CB60, et en réfléchissant sur ta formule, j'ai compris:
le décalage du nombre de ligne (avec EQUIV) est conditionnelle (SI) selon la position d'une valeur numérique (9^9) ou d'une valeur texte (zzz).
Par contre, ce que je ne sais pas, c'est: "pourquoi zzz pour du texte ?".
Merci encore à toi.
Bonjour à tous.
Tout d'abord merci pour votre précieuse expertise qui me permet de trouver pas mal de fonctions que j'utilise après dans mon boulot.
Néanmoins, je souhaiterais vous soumettre ce problème qui fait suite à la réponse apportée à la demande de ce topic.
Dans un fichier de suivi de chantier, j'ai utilisé ces formules :
=INDEX(I15:XX15;EQUIV(VRAI;I15:XX15<>"";0)) (première valeur de la ligne)
=INDEX(I15:XX15;EQUIV(9^9;I15:XX15;1)) (dernière valeur de la ligne)
ça marche.
Mais ce que je voudrais c'est que la valeur obtenue dans la cellule de la formule sois celle d'une autre cellule, située 9 lignes plus haut que la première et la dernière cellule inscrite et qui comporte une date afin d'incrémenter un GANTT.
Voilà, donc je souhaiterais, grâce à une formule, que la valeur de E15 soit égale à L6 et celle de F15 à J6.
Bien sûr, il faut que je puisse faire glisser ma formule sur toute la colonne et qu'elle se reporte sans erreurs.
J'espère avoir été assez clair et je vous remercie d'avance pour le temps que vous pourrez consacrer à mon problème.