Regrouper 2 colonnes en une sans doublons

Bonjour à tous
J'ai deux colonnes (A et B) avec des adresses emails dans chacune. J'aimerai pouvoir dans la colonne C avoir la totalité des emails des colonnes A et B et si possible sans doublons.
Est ce possible en formule ?
Merci
Zesuila

Bonjour,

en même trié !

=sort(unique(query({A1:A;B1:B};"select * where Col1<>'' ")))

en espérant que ce soit conforme à tes paramètres régionaux car tu n'as pas mis de lien vers un exemple.

Parfait !
Merci beaucoup Mikhail Staliyevich
Il faut vraiment que je bosse ce "query".
Zesuila

https://www.sheets-pratique.com/fr/query

voici

=sort(unique(query({A2:A\B2:B;A2:A\C2:C};"select Col2 where Col1='ok' ")))

Encore merci de ton aide. Là ça ne fonctionne pas. j'ai dû mal m'expliquer. (et je pensais pouvoir y arriver seul avec ce que tu m'avais donné comme formule)
Je vais essayer d'être plus précis. :
J'ai une feuille "cotisation" dans laquelle en colonne A j'ai une liste de validation, dont "OK"
J'ai une autre feuille " U7" dans laquelle en colonnes F et R j'ai des emails (quelquefois en doublon)
Je voudrais dans la feuille "Email" en colonne A récupérer tous les emails (donc colonne F et R sans doublon) à condition qu'il y est dans la ligne de "cotisation" le mot "ok"
J'espère que c'est plus explicite pour toi.
En tout cas je te remercie une nouvelle fois.

Mets un lien vers une copie de ton fichier. Je saurais a minima quelles sont les paramètres régionaux.

Je ne sais pas si c'est la bonne manip pour le lien
https://docs.google.com/spreadsheets/d/1lKCemusJCVWzMCs5vuQoHTlvk-XOmVGwdkCX7EwjCGk/edit?usp=sharing

ok, je regarde

pas simple ... !

à vérifier

=sort(unique(query(arrayformula({row(A!C3:C9)\A!C3:C9;row(A!D3:D9)\A!D3:D9});"select Col2 where Col1 matches '"&textjoin("|";true; arrayformula(if(B!A2:A<>"OK";;MATCH(B!B2:B&B!C2:C;arrayformula(A!A:A&A!B:B);0))) )&"' ")))

ouahhh ! Ca fonctionne ! vraiment génial !
Merci beaucoup Mikhail
je vais tâcher maintenant de comprendre ce code
bon week end à toi

cela devient extrêmement complexe !! parce que les données sont partagées et que l'on a 2 colonnes (nom et prénom) pour identifier !

Bon je reviens vers toi !
J'ai transcris ta formule avec mes noms d'onglets mais cela ne fonctionne pas.
Je pense que cela vient de là : select Col2 where Col1 matches '"&textjoin("|";VRAI;
Lorsque je valide ce code dans mon fichier, rien n'apparait (par contre aucune erreur).Si je change par exemple col2 en col1 j'ai une ligne qui se rempli avec un chiffre et non un email (et je devrais avoir deux lignes avec mail de rempli)
Peux tu m'expliquer le sens de ce code ? j'essaierai de trouver ensuite ce qu'il faut mettre

C'est que ton fichier n'est pas représentatif !

si je découpe la formule

je fais ici un tableau comportant en Col1 la ligne et en Col2 la valeur de la colonne C, puis de la colonne D, les 2 étant superposés

=sort(unique(query(arrayformula(
{row(A!C3:C9)\A!C3:C9;row(A!D3:D9)\A!D3:D9})

je sélectionne ensuite la colonne 2 (les données, pas les n° de ligne en Col1)

;"select Col2 

quand le numéro de ligne correspond à la liste des n° de ligne issue d' une recherche du nom&prénom onglet B dans la base de données onglet A

where Col1 matches 
'"&textjoin("|";true; arrayformula(if(B!A2:A<>"OK";;MATCH(B!B2:B&B!C2:C;arrayformula(A!A:A&A!B:B);0))) )&"' ")))

ta structure est complexe => la formule est complexe, mais elle fonctionne !

YESSS ! j'ai trouvé ! en fait erreur dans mes noms de feuille.
Ca fonctionne sur mon fichier

Franchement ! Impressionné par tes compétences. Bravo

Une inquiétude quand même, essaie de mettre plus de 30 lignes, et mets ls lignes du début pas ok, pour voir si le "match" des lignes ne serait pas à retravailler un poil !

Bonjour Mikhail
Merci pour les explications.
Je viens de tester ton "inquiétude". Et tout à l'air correct.
Vraiment un grand merci à toi. Passes un bon week-end