Ouvrir dossier telechargements

Bonjour a tous,

je souhaiterais savoir comment faire ouvrir une boitier de dialog "ouvrir" directement dans le dossier téléchargements mais pas avec le chemin directe car la macro serais pour être utilisée avec différents utilisateur.

Merci a tous pour vos reponses

Hello,

qqch comme ça :

Dim fld As FileDialog
  Dim strFilePath As String
  Set fld = Application.FileDialog(msoFileDialogOpen)
  With fld
    .InitialFileName = "C:\Users\TUTU\Downloads"
    .Show
  End With
  strFilePath = fld.SelectedItems(1)

R@g

Bonjour

merci pour la réponse mais justement le chemin est dédier a un utilisateur et ma macro doit fonctionner sur plusieurs ordi sans que je soit obligé de modifier le chemin.

Merci

Bonjour à tous,

Peut être avec ce code :

Chemin = Environ("USERPROFILE") & "\Downloads"

Pierre

Bonjour,

Voici un essai si j'ai bien compris :

Sub OuvrirFichier()

Dim fld As FileDialog
Dim dossiers
Dim strFolderPath As String

Set fld = Application.FileDialog(msoFileDialogOpen)

With fld
    dossiers = Split(.InitialFileName, "\")
    ReDim Preserve dossiers(0 To 2) 'en supposant que le modèle soit toujours le même (DISQUE\USERS\NOM USER\)
    strFolderPath = Join(dossiers, "\") & "\Downloads"
    if dir(strFolderPath, vbdirectory) = "" then msgbox "erreur chemin": exit sub
    .InitialFileName = strFolderPath & "\"
    .Show
    .Execute
End With

End Sub

On essaie d'ouvrir le dossier téléchargements pour des utilisateurs variables...

Cdlt,

bonjour

je te propose de sortir des dialogs excel et d'utiliser les dialog vba

teste simplement ce code

il propose tout les fichier dans la fenetre

Sub ouvre2()
'ouverture un !! ou !!! plusieurs !!  fichiers en gardant la touche control appuyée ou en sélectionnant par glissage (souris
    Dim Fichiers As Variant, i&
    ChDrive ("c:\")    'cible le dique dur C comme disque courant 
    ChDir Environ("userprofile") & "\Downloads"   'cible le dossier par defaut en le mettant comme dossier courant"
    Fichiers = Application.GetOpenFilename("Tout fichiers (*.*), *.*", 1, "ouvrir un fichier", , True)
    If IsArray(Fichiers) Then 'si plusieurs sélectionnés
        For i = LBound(Fichiers) To UBound(Fichiers)
            MsgBox Fichiers(i)
        Next
    ElseIf Not IsArray(Fichiers) Then ' si un seul sélectionnés
        If Fichiers = False Then Exit Sub' si annulé
        MsgBox Fichiers
    End If
End Sub

bien sur on peut forcer uniquement une extensions de fichier précise

exemple uniquement tout les fichiers excel

Fichiers = Application.GetOpenFilename("Tout fichiers (*.xls*), *.xls*", 1, "ouvrir un fichier", , True)
   

on peut aussi forcer plusieurs extensions

exemple pour des fichier image de différentes extensions

 Fichiers = Application.GetOpenFilename("fichiers Images (*.jpg*;*.png;*.bmp;*.tif), *.jpg*;*.png;*.bmp;*.tif", 1, "ouvrir un fichier", , True)
   

Bonjour,

merci a tous pour votre aide. patricktoulon ma apporter la solution a mon problème.

Merci, merci

Micka17