Changement de colonne en fonction d'une variable

Bonjour.

J'ai fait un code pour mettre la colonne D comme variable (nommée col).

Je veux ainsi copier un code dans avoir à changer le nom de colonne dans chaque ligne.

Ca ne fonctionne pas :(

Pouvez-vous m'éclairer.

'************************
'macro pour copier cellule de Remplir vers GW_level (partie qui fonctionne)
'**************************

Worksheets("gw_level").Activate

Cells(Rows.Count, 1).End(xlUp)(2).Select

ActiveCell.Value = Worksheets("remplir").Range("c9").Value 'A:nom de piezometre
ActiveCell.Offset(0, 1).Activate 'déplacement d'une colonne
ActiveCell.Value = Worksheets("remplir").Range("c6").Value 'b: Date du relevé
ActiveCell.Offset(0, 1).Activate 'déplacement d'une colonne
ActiveCell.Value = Worksheets("remplir").Range("c10").Value 'C: Date échantillon A
ActiveCell.Offset(0, 1).Activate 'déplacement d'une colonne
ActiveCell.Value = Worksheets("remplir").Range("c11").Value 'D: Date échantillon B
ActiveCell.Offset(0, 1).Activate 'déplacement d'une colonne
ActiveCell.Value = Worksheets("remplir").Range("c12").Value 'E Date échantillon c... et ainsi de suite

Partie problématique est celle là :

'********************************************
'procedure pour changer de changer de collone et inscrire le no de collone comme varibale
'**********************************
Worksheets("remplir").Activate
Dim col As Variant
col = D
If Range("D9") <> "" Then ' si la colonne a une valeur activer la page GW_level
Worksheets("gw_level").Activate
Cells(Rows.Count, 1).End(xlUp)(2).Select 'Choisir la dernière cellule vide du tableau
ActiveCell.Value = Worksheets("remplir").Range("col9").Value 'A:nom de piezometre
End If

Bonjour,

Un essai ...

Sub ijijijiji()
Dim DLig As Integer
Dim Col As Integer
Dim WG As Worksheet
Dim WR As Worksheet

    Set WG = Worksheets("gw_level")
    Set WR = Worksheets("Remplir")

    For Col = 3 To 7    ' colonne C à G

        '********************************************
        'procedure pour changer de changer de colonne et inscrire le no de colonne comme variable
        '**********************************

        If WR.Cells(9, Col) <> "" Then      ' si la colonne a une valeur activer la page GW_level
            DLig = WG.Cells(Rows.Count, "A").End(xlUp).Row + 1        'Choisir la dernière cellule vide du tableau
            WG.Cells(DLig, "A") = WR.Cells(9, Col).Value        'A:nom de piezometre
            WG.Cells(DLig, "B") = WR.Cells(6, Col).Value        'b: Date du relevé
            WG.Cells(DLig, "C") = WR.Cells(10, Col).Value       'C: Date échantillon A
            WG.Cells(DLig, "D") = WR.Cells(11, Col).Value       'D: Date échantillon B
            WG.Cells(DLig, "E") = WR.Cells(12, Col).Value        'E Date échantillon c... et ainsi de suite
        End If
    Next Col
End Sub

ric