Travail de cours d'info

AmauryG19 a écrit :

J'avoue ne pas dutout saisir comment remplir K3, j'avais tout donné pour remplir la cellule déjà

Il reste que tu y utilises (dans tes 2 EQUIV) les références à A14 et C1, au lieu de K2 et K3 (ce qui est demandé dans les consignes). Vois si tu peux corriger ça

Désolé de l’inactivité mais j'avoue ne pas trop regarder mon tel / ordi le dimanche

Voici donc la formule après modification : "=INDIRECT(ADRESSE(EQUIV(K2;A:A;0);EQUIV(K1;1:1;0)))"

Ah mais je ne suis pas pressé par le temps, moi

Tu as testé cette formule, dans le fichier où on a calculé les heures en colonne A (de A3 à A25), en ajoutant 1/24^e à chaque heure précédente ? Et si tu saisis 15:00 en K2, tu as le bon résultat qui s'affiche ?

La formule correspond plutôt bien à l’énoncé je pense sachant que je peux changer l'heure ou la date et que cela affiche bien la nouvelle valeur.

Bonsoir,

Ma question était plus précise: tu as testé avec 15:00 en K2 ? Tu as bien, en colonne A les calculs qui ajoutent un 24^e à la cellule au-dessus ?

Je te pose la question, parce que moi, j'ai une erreur, dans ce cas-là ! (j'ai fini par trouver une explication ... mais elle ne tient plus la route si tu me dis que dans les mêmes conditions, les bons résultats sont affichés chez toi !?)

Ah oui en effet cela me traduit une erreur ! J'avais changé la valeur de K2 en sélectionnant la cellule en A et pas manuellement :/

AmauryG19 a écrit :

Ah oui en effet cela me traduit une erreur !

En fait, en prenant, en A17, la valeur de A16 (qui est un nombre avec un paquet de décimales) et en y ajoutant 1/24^e (un autre nombre avec un paquet de décimales), on obtient un résultat différent (à la 8^e ou 9^e décimale) de la valeur encodée en K2. Comme le dernier argument de la fonction EQUIV est '0', on demande à Excel de trouver la correspondance exacte entre la valeur de K2 et celle de A17 ... ben la différence, même à la x^e décimale, génère une erreur.

On va donc modifier la formule en A3 et écrire

=(HEURE(A2)+1)/24

On recopie jusqu'en A25 ... et on ne devrait plus avoir de souci, cette fois !

Il reste que tu dois gérer son histoire d'erreur en K1 ou K2 et afficher un message. Avec ta formule actuelle, on va devoir "chipoter" un peu En K3, je ne vois que quelque chose comme

=SI(OU(NB.SI(B1:H1;K1)=0;NB.SI(A2:A25;K2)=0);"erreur";INDIRECT(ADRESSE(EQUIV(K2;A:A;0);EQUIV(K1;1:1;0))))

Par contre, en utilisant INDEX/EQUIV comme on l'a fait dans l'autre exercice, on peut écrire plus simplement:

=SIERREUR(INDEX(B2:H25;HEURE(K2)+1;EQUIV(K1;B1:H1;0));"Erreur")

Tu me diras si tu as besoin d'explications ... mais ce sera pour demain !

On s'attaquera aussi à ces moyennes, en ligne 27, qui doivent s'adapter aux heures renseignées en K5 et K6. Celle-là, je te l'offre (c'est un cadeau de la maison!). En B27:

=ARRONDI(MOYENNE(DECALER(B$2;HEURE($K$5);0;HEURE($K$6)-HEURE($K$5)+1));1)

... explications pour demain aussi. J'arrête pour aujourd'hui, moi

Oulalala ou je veux bien des explications ! J'avoue que c'est peut être pas de mon niveau donc ca va me faire progresser c'est super !

Tout marche correctement ducoup maintenant, je pensais que mes moyennes étaient bonnes mais ducoup non x)

Salut,

Tes moyennes étaient bonnes, mais ne tenaient pas compte de la consigne qui dit

Si on change la valeur de K5 ou de K6, le résultat doit s’ajuster sans qu’on change la formule

Et tu as besoin d'explications pour quelle(s) formule(s) ?

Ah oui il est vrai !

La fonction OU dans K3, je ne sais pas trop ce qu'elle définie ici. Et comment fonctionne la fonction HEURE utilisée en B27 et A3

En K3, ta fonction INDIRECT(ADRESSE(etc. renvoie 0 si la date en K1 ou l'heure en K2 n'existent pas en ligne 1 ou colonne A. Pour tester s'il y a une erreur (voir consignes), on ne peut pas juste décider que si la valeur de retour est '0' il y a nécesairement une erreur (dans le tableau des températures, il pourrait y avoir un zéro).

La solution que je propose vérifie si la date en K1 est absente de la plage B1:H1 OU si l'heure en K2 est absente de la plage A2:A25. Si une de ces 2 conditions se vérifie, on affiche "erreur".

Pour la fonction HEURE, tu aurais pu chercher un peu: c'est pas bien compliqué si tu écris dans une cellule 17:38:47, la fonction HEURE va renvoyer 17 ... c'est dingue, non ?

Ok j'ai saisis comment ca fonctionne ! Je pensais que c'était plus dur que ca x)

Ah je croyais que ca traduisait en heure ce qu'on renseigne dans la cellule

Si tu t'intéresses (vraiment !) à Excel, tu ne pourras pas le faire "à l'économie": tu devras chercher, creuser, tester, te prendre la tête parfois (souvent ?), tout effacer et recommencer ... et j'en passe !

Voici ce que je peux te dire de la fonction DECALER:

cette fonction permet de créer une référence à une plage de cellules (comme si tu la sélectionnais avec ta souris).

La syntaxe est: DECALER(Réf, lignes, colonnes, hauteur, largeur)

Vois les choses comme le "viseur" d'un appareil photo.

Dans la formule

DECALER(B$2;HEURE($K$5);0;HEURE($K$6)-HEURE($K$5)+1)

• on "vise", comme point de départ, la cellule B2. Dans l'argument "Ref", la colonne B est relative (pas de '$' devant 'B'), de manière qu'en copiant la formule à droite, on "passera" automatiquement en colonne C, puis D, etc.
• On descend ensuite du nombre de lignes renseignées par l'heure de début. Si c'est 11:00, ben on descend de 11 lignes, puisque B2 est à hauteur de 00:00 et le 11 est donné par HEURE(K5).
• Comme la moyenne est à calculer en B27, on reste dans la colonne B ... donc on "décale" à droite de ... 0 colonnes.
• Il faut ensuite "zoomer" (ou "dézoomer", si ça existe), puisqu'on veut la plage comprise entre l'heure de début (K5) et l'heure de fin (K6). Le nombre de lignes est déterminé par HEURE($K$6)-HEURE($K$5)+1. Si heure de début = 11:00 et heure de fin = 14:00, 14-11+1 donne bien 4 heures (ou 4 lignes ici). La consigne disant "température moyenne entre les heures saisies en K5 et en K6, ces deux valeurs étant comprises ".
• La largeur n'est pas précisée dans la formule, donc elle reste de 1, par défaut

Je ne t'explique pas MOYENNE, ni ARRONDI

Ok ca y est je comprend mieux ! Sympa comme fonction et peut être très utile !

En effet arrondi et moyenne je gère plutôt bien

Je n'ai rien à faire ici, mais je voulais juste dire que je trouve cette collaboration GENIALE! Chapeau U.milité pour le temps passé à aider. Et bravo Amaury pour avoir tout suivi et avoir fait le travail plutôt qu'attendre qu'il tombe tout cuit!

(et au fait, qu'est-ce que ça a donné comme résultat auprès du prof?)