Detection de borne haute et basse
Bonjour à toutes et à tous,
Je viens vous voir pour faire appel à vos talents sur tableur excel car j'ai un petit soucis qui j'espère peut être résolu sur excel.
Sur la base d'un tableau qui comprend un certain nombre de chiffres, est il possible par le biais d'une formule que excel puisse detecter si un chiffre est compris entre telle et telle valeur du tableau?
Si c''est effectivement possible j'aurais aimé par la suite faire le calcul suivant, bon ça je peux logiquement le faire : (Chiffre - borne basse) / (borne haute - borne basse).
Je vous joins en pièce jointe le tableau avec exemples.
Merci pour votre aide.
Cordialement.
Bonsoir,
je pense qu'ainsi, ce devrait être plus simple :
=C5-ENT(C5)au format %
Bonne soirée
felix a écrit :Bonsoir,
je pense qu'ainsi, ce devrait être plus simple :
=C5-ENT(C5)au format %
Bonne soirée
Bonsoir et merci felix pour la rapidité de votre réponse.
Mais malheuresement ca ne répond pas totalement à ma question. J'ai oulié de préciser (pardonnez moi) que les chfffres contenue dans le tableau de référence sont suceptibles de changer et ne sont pas forcement des chiffres ronds.
Ce qu'il faudrait c'est qu'excel puisse vérifier à chaque fois ou se situe un chiffre quelconque par rapport aux chiffres contenue dsns le tableau de référence, et déterminer ainsi la borne basse (chiffre par défaut du tableau de référence) et la borne haute (chiffre par excès du tableau de référence).
Par exemple j'ai un tableau de référence contenant les chiffres suivants:
1
2.3
3.6
4.9
5
7
10.1
12.6
Je prend un chiffre quelconque de 4.1.
Excel devra détecter dans le tableau de référence que 4.1 est compris dans le tableau de référence entre 3.6 (valeur par défaut donc borne basse) et 4.9 (valeur par excès et donc borne haute).
Par la suite, faire le calcul suivant:
(Chiffre quelconque - borne basse) / (borne haute - borne basse).
Encore une fois merci beaucoup pour votre aide.
Cordialement.
Bonsoir,
Essaye la formule matricielle suivante, A1:A8 contenant les nombres donnés en exemple et B1 le chiffre quelconque, formule à valider avec les touches CTRL + MAJ + ENTREE :
=(B1-MAX(SI((B1-(A1:A8)>0);A1:A8;"")))/(MIN(SI((B1-(A1:A8)<0);A1:A8;""))-MAX(SI((B1-(A1:A8)>0);A1:A8;"")))A tester aussi avec validation matricielle :
=MIN(SI(B1-A1:A8>=0;B1-A1:A8;""))/(MIN(SI((B1-A1:A8<=0);A1:A8-B1;""))+(MIN(SI(B1-A1:A8>=0;B1-A1:A8;""))))Bonjour à tous
voici une formule normale
Edit Amadéus: J'aurai mis "Voici une autre formule", sinon, nous pourrions passer pour des adeptes de la formule anormale. Au fait, c'est quoi, la différence?
=(C5-INDEX($A$4:$A$21;EQUIV(C5;$A$4:$A$21;1)))/(INDEX($A$4:$A$21;EQUIV(C5;$A$4:$A$21;1)+1)-INDEX($A$4:$A$21;EQUIV(C5;$A$4:$A$21;1)))à placer en D5[/code]
Bonjour à tous,
Merci beaucoup pour votre aide à tous! Je ne suis pas chez moi mais je teste des ce soir l'ensemble des solutions et je vous tiens au courant.
Encore une fois un grand merci.
Cordialement.
Bonsoir,
Après avoir tester ça marche nickel. Encore une fois un grand merci à vous.
Fredo.