Recherche v + petite valeur
Bonjour à tous!
J'ai un souci avec une formule :
je souhaiterais combiner la fonction recherchev avec petitevaleur pour rechercher l'horaire de connexion la plus petite en fonction d'un nom mais ma formule me renvoie la première valeur qu'elle trouve et non la plus petite.
=PETITE.VALEUR(RECHERCHEV("*"&H1&"*";A:B;2;FAUX);1)
avez-vous une solution car je sèche ^^
merci beaucoup
bonne fin de journée!
bonjour
a la volée
= MIN(si ( la colonne des noms = H1; la plage des heures ;""))
la formule est matricielle donc a valider avec les 3 touches Ctrl MAJ Entrée en simultané
met une vrai Pj car c'est impossible de travailler sur photo
cordialement
Bonjour le forum,
=MIN(SI(A2:A10=H1;B2:E10;""))Formule matricielle.
re
pas sur de pouvoir faire marcher sur un téléphone ,tu vas avoir des soucis pour valider ( je crois)
cordialement
re
essaye celle ci qui ne nessecite pas de validation spécifique
=SOMMEPROD(PETITE.VALEUR((A2:A6=H1)*(B2:E6);SOMMEPROD((A2:A6<>H1)*(B2:E6>0))+1))cordialement
Re,
j'ai mal exprimé mon besoin ^^' j'en suis dsl.
Un fichier en PJ
je souhaite l'heure de connexion la plus petite pour Paul sur la journée du lundi, donc la recherche se fait sur la colonne des jours.
Car paul et paul2 sont la même personne, il a juste 2 profils pour se connecter.
merci encore pour votre aide
bonne soirée!
=SI(H1<>"Paul";MIN(SI((A2:A5=H1);B2:B5));MIN(SI(GAUCHE(A2:A5;4)=H1;B2:B5;"")))Formule matricielle.
Bonjour à tous!
Merci beaucoup pour vos réponse, c'est tout à fait ça enfin presque car j'ai oublié les connexions à 00:00:00 donc il faudrait que la formule ne prenne pas en compte le 00:00:00 quand elle recherche la plus petite.
00:00:00
09:25:00
08:25:12
--> Du coup la plus petite est 08:25:12 et pas 00:00:00
la formule ci dessous ne prends pas en compte les connexions nulles mais je n'arrive pas à l'associer à la formule de Tulipe_4
=MIN(SI(B:B<>0;B:B))
Sans le problème posé par "Paul" :
=MIN(SI((A2:A5=H1)*(B2:B5>0);B2:B5))bonjour
cela peux se transformer en
=MIN(SI(ESTNUM(CHERCHE(D1;A2:A5)*1);SI(B2:B5=0;"";B2:B5);""))toujours matricielle
cordialement
D2 :
=SI(D1<>"Paul";MIN(SI((A2:A5=D1)*(B2:B5>0);B2:B5));MIN(SI((GAUCHE(A2:A5;4)=D1)*(B2:B5>0);B2:B5;"")))
Bonjour,
dsl pour le délai de réponse :s
les 2 formules sont efficaces!
Merci beaucoup pour votre aide.
je peux clôturer!
Bonne journée!
Cordialement,