Affiche le premier mot et la 1ére lettre du mot suivant
Bonsoir
Pouvez-vouos m'aider à trouver une formule qui m'affiche le 1er mot et la 1ére lette du mot suivant.
Exemple :
DUPONT Jean devra s'afficher de la façon suivante DUPONT J
Merci pour votre aide
COUNTRY64 a écrit :Bonsoir
Pouvez-vous m'aider à trouver une formule qui m'affiche le 1er mot et la 1ére lettre du mot suivant.
Exemple :
DUPONT Jean devra s'afficher de la façon suivante DUPONT J
Merci pour votre aide
Bonsoir,
essaie avec cette formule :
=GAUCHE(A1;TROUVE(" ";A1;1)+1)Si Dupont Jean est dans la cellule A1
Bonsoir
Sur la base qu'un espace sépare les 2 mots :
=GAUCHE(A1;CHERCHE(" ";A1)+1)Amicalement
Nad
Edit : Collision ... Salut Felix
Merci felix
C'est exactement ça.
Bonjour
Je reprends ce post, je ne sais pas si cela est autorisé car j'ai besoin d'une précision.
Cette formule fonctionne trés bien mais petit HIC pour les noms composés comme :
SAINT FAUSTIN Julien ce qui donne SAINT F
Merci pour votre aide
Bonne journée
Bonjour,
Essaye ceci --> =GAUCHE(A1;CHERCHE(" ";A1)-1)&" "&GAUCHE(DROITE(A1;NBCAR(A1)-CHERCHE(" ";A1));1)
Amicalement
Dan
Bonjour,
Une autre solution avec une formule matricielle.
On part du principe que le nom est toujours en majuscules et que pour le prénom on a la 1ère lettre en majuscule et les suivantes en minuscules.
Il faut donc déterminer le rang de la 1ère lettre minuscule.
=GAUCHE(A1;EQUIV(FAUX;EXACT(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1);MAJUSCULE(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1)));0)-1)Formule matricielle à valider par CTRL + MAJ + ENTREE
@+
Bonsoir THIBO
J'ai essayé ta formule mais elle ne fonctionne pas , peut-être ai-je fait une Erreur.
Je joins mon essai
https://www.excel-pratique.com/~files/doc/mrkMDClasseur1.xls
Bonne soiree
Bonsoir
Non, pas d'erreur dans ta formule, mais une erreur dans la validation.
Cette formule est matricielle. Cela veut dire que tu dois sélectionner la cellule contenant la formule, positionner le curseur de la souris dans la barre de formule et appuyer simultanément sur les 3 touches Ctrl+Maj+Entrée pour qu'Excel mette les accolades et active la formule.
Cordialement
Merci à tous les deux
Bonjour à tous
Je reouvre ce post car je viens de m'apercevoir que je n'arrive pas à ajourter la condition :
Si A1 est vide alors affiche rien sinon ......
Autrement cette formule fonctionne trés correctement
Merci pour votre aide
Bonjour,
Une version allégée de la formule qui permet de gérer les cellules vides :
=SI(A1="";"";GAUCHE(A1;EQUIV(VRAI;CODE(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1))>96;0)-1))Toujours matricielle, donc validation par CTRL + MAJ + ENTREE
@+
re,
Une version plus complète qui permet de gérer les cellules vides, celles qui ne contiennent que des majuscules, que des minuscules ou que des nombres
Inconvénient pour ces derniers (les nombres), ils sont retournés sous forme Texte.
La formule :
=SI(OU(EXACT(A1;MAJUSCULE(A1));EXACT(A1;MINUSCULE(A1));A1="");A1&"";GAUCHE(A1;EQUIV(VRAI;CODE(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1))>96;0)-1))Toujours matricielle, donc CTRL + MAJ + ENTREE
La difficulté était d'arriver à gérer la limite des sept niveaux d'imbrication de fonctions.
@+
Bonsoir THIBO
J'ai testé la formule suivante :
=SI(A1="";"";GAUCHE(A1;EQUIV(VRAI;CODE(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1))>96;0)-1))
Elle fonctionne bien mais un Hic quand il n'y a pas de prénom ou seulement la première lettre alors s'affiche N/A.
Merci
Bonsoir Country64,
Regarde la formule que je t'ai proposée à 18;59 (heure Forum
Elle doit répondre aux problèmes que tu évoques
@+
Thibo,
J'ai testé ta deuxième formule mais elle ne fonctionne pas dans les cas suvants :
ARTIGUES A donne N/A
BLUESTHOMER donne N/A
Autrement OK pour le reste et même les nom composés SAINT FAUSTIN Julien ....
Bonjour Country,
Un essai avec la dernière formule que je t'avais proposé.
Je ne rencontre pas de problème ...
Voir le fichier avec les exemples que tu donnes
https://www.excel-pratique.com/~files/doc/Country64.zip
@+
Bonsoir THIBO
J'ai repiqué la formule sur ton exemple et "EUREKA" çà marche.
Bravo Thibo
Juste un dernier petit détail : Est-il possible d'ajuster la formule dans le cas d'un prénom composé (Jean Pierre ...).
Un grand merci
Bonjour,
Un essai pour gérer les prénoms composés :
=SI(OU(A1="";SOMMEPROD((CODE(STXT(A1&" ";LIGNE(INDIRECT("1:"&NBCAR(A1)+1));1))>96)*1)=0);A1;GAUCHE(A1;EQUIV(VRAI;CODE(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1))>96;0)-1))&SI(MAX((CODE(STXT(A1&" ";LIGNE(INDIRECT("1:"&NBCAR(A1)+1));1))<91)*LIGNE(INDIRECT("1:"&NBCAR(A1)+1)))-1=EQUIV(VRAI;CODE(STXT(A1&"µ";LIGNE(INDIRECT("1:"&NBCAR(A1)+1));1))>96;0)-1;"";" "&STXT(A1;MAX((CODE(STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1))<91)*LIGNE(INDIRECT("1:"&NBCAR(A1))));1))Voir le fichier joint.
https://www.excel-pratique.com/~files/doc/Nom_Initiales_Prenom.zip
@+