Bonsoir,
ci joint le fichier avec un rajout de deux colonnes : transporteur et prix.
En fonction de l'article et du pays ces deux valeurs se mettent à jour en fonction des tableaux du dessous.
Les formules ?
Une combinaison de INDEX et EQUIV.
Les expliquer ? Humm pas facile pour moi...
La formule "Prix" :
=INDEX($B$42:$Q$63;EQUIV($B6;$B$42:$B$63;0);EQUIV($F6;$B$42:$Q$42;0))
EQUIV($F6;$B$42:$Q$42;0)
ici on recherche la valeur F6 (pays, par exemple Allemagne) dans la lignes de cellules allant de B42 à Q42, avec comme critère 0=valeur exacte
la fonction renvoie un numéro, ce numéro dans ce cas est un numéro de colonne par rapport à B42, donc
dans notre exemple (Allemagne) la fonction renvoie 7 alors cela correspondra à la colonne H car B=1 C=2 etc ce qui est bien la colonne de l'Allemagne ! YES !
EQUIV($B6;$B$42:$B$63;0)
ici on cherche le numéro de ligne de la valeur en B6 (article, par exemple CT08001E) dans LES lignes de cellules allant de B42 à B63, avec en critère valeur exacte = 0.
la fonction renvoie un numéro, ce numéro dans notre cas va correspondre à un numéro de ligne par rapport à B42, donc
dans notre exemple (CT08001E) la fonction renvoie 10 alors cela correspondra à la ligne 51 car 42=1 43=2 etc ce qui est bien la ligne de l'article CT08001E ! YES !
=INDEX($B$42:$Q$63; valeur "ligne" =EQUIV($B6;$B$42:$B$63;0); valeur "colonne" =EQUIV($F6;$B$42:$Q$42;0))
INDEX permet de connaître la valeur qui se trouve à l'intersection d'une colonne et d'une ligne dans une table :
la table : B42:Q63
la ligne : EQUIV($B6;$B$42:$B$63;0)
la colonne : EQUIV($F6;$B$42:$Q$42;0)
YES ! YES ! et re YES !
La fonction trouve le prix en fonction du pays et de l'article
Pour la formule du transporteur c'est "presque pareil" sauf que pour la ligne je crée un "rajout" de 37 ligne afin de "passer" sur le deuxième tableau... car au niveau des colonnes ce sont les mêmes (ouf!) et la table de l'INDEX doit aussi prendre en compte ce deuxième tableau donc elle est égale à : B42:Q99
=INDEX($B$42:$Q$99;37+EQUIV($B6;$B$42:$B$63;0);EQUIV($F6;$B$42:$Q$42;0))
Voilà en espérant avoir été clair...
Ceci dit les tables de recherche peuvent être remplacer par des zones nommées...
@ bientôt
LouReeD