Les accents dans Excel

Bonjour,

SVP Est-ce que vous pourriez me dire comment rétablir l'écriture avec accent circonflexe. aigu etc

c'est une application qui provient de l'anglais je crois

Merci de votre travail c'est très apprécié

Pierre

Salut,

Je ne comprends pas très bien ta question, le problème pouvant venir selon moi de plusieurs endroits. Peux-tu nous fournir un fichier exemple démontrant ton souci ?

A te relire.

Bonjour,

voici le fichier, lorsque je fais copier/coller dans une cellule du fichier, les mots qui ont des accents

par exemple "découvrez" le é devient bizarre.

fichier joint

Merci

Pierre

Ok mais ce que tu nous donnes n'est pas un fichier excel ! c'est un fichier csv.

C'est un problème non pas d'excel qui accepte maintenant le codage unicode (utf-8), mais dans ton cas

• soit un problème qui me semble-t-il vient de l'amont : à partir de quoi a été fait ce fichier csv ?
• soit lié au format de fichier csv lui-même.

OK je vais vérifier pour un fichier .csv

désolé je ne connais pas les fichiers csv alors j'étais convaincu que c'était un excel

Merci pour l'information

Pierre

Bonjour,

p'tite démonstration à l'ancienne pour lire un fichier texte codé en UTF-8 :

Sub Demo()
Const CSV = "D:\Tests4Noobs\scheduled-messages.csv"
Dim SP$()
If Dir(CSV) = "" Then Beep: Exit Sub

With CreateObject("ADODB.Stream")
    .Charset = "UTF-8"
    .Open
    .LoadFromFile CSV
    SP = Split(.ReadText, vbNewLine)
    .Close
End With

With Feuil1.Cells(1)
    .CurrentRegion.Clear
    .Resize(UBound(SP) - (SP(UBound(SP)) > "")).Value = Application.Transpose(SP)
End With
End Sub

Gros merci

Pierre

Bonjour,

Une possibilité :

Change l'extension en .txt et ouvre-le avec excel.

Dans la boite de dialogue choisi 'Origine du fichier : 65001 : Unicode (UTF-8)'

C'est assez loin dans la liste, commence par le bas.

eric

Oui bien vu Eric ! Mais effectivement ne passe pas en .csv, il faut renommer le fichier en .txt …

Sub Macro1()
 Const TXT = "D:\Tests4Noobs\scheduled-messages.txt"
If Dir(TXT) = "" Then Beep: Exit Sub
Workbooks.OpenText TXT, 65001, , xlDelimited, xlNone
End Sub

Charger un fichier csv au format UTF-8 sans le renommer et directement dans une cellule précise d'une feuille de calculs

via la fonctionnalité d'Excel d'importation à partir d'un fichier texte du menu Données en manuel comme par code :

Sub Demo2()
 Const CSV = "D:\Tests4Noobs\scheduled-messages.csv"
If Dir(CSV) = "" Then Beep: Exit Sub

With Feuil1
    .Cells(1).CurrentRegion.Clear

    With .QueryTables.Add("TEXT;" & CSV, .Cells(1))
               .AdjustColumnWidth = False
                    .RefreshStyle = xlOverwriteCells
               .TextFileParseType = xlDelimited
                .TextFilePlatform = -535   ' ou 65001
           .TextFileTextQualifier = xlTextQualifierDoubleQuote
         .Refresh False:  .Delete
    End With
End With
End Sub

C'était mon premier choix mais comme l'aide VBA de QueryTable XlPlatform ne propose que les trois premiers types de fichiers

j'avais alors opté pour ADODB …