La fonction EXACT différence MAJ/min
Bonjour a tous,et toutes
Qqn serait il comment faire la différence entre majuscule et minuscule dans une formule excel.
J'ai regardé EXACT et j'arrive pas a lui faire retourner un nombre ( c'est une fonction booléenne? soit 0 ou 1 ?)
Alors ma demande est pour calculer le nombre minimal de cellules a la suite ne comprenant pas de "p" sur un intervalle d'une ligne..
avec :
=MIN(SI(FREQUENCE(SI($O24:$DG24<>"P";COLONNE($O24:$DG24));SI($O24:$DG24="P";COLONNE($O24:$DG24)))<>0;FREQUENCE(SI($O24:$DG24<>"P";COLONNE($O24:$DG24));SI($O24:$DG24="P";COLONNE($O24:$DG24)))))
ca marche mais ca ne prend pas en compte la différence entre les "p" et "P" ce qui me fait un bug dans certain cas.
j'ai essayé :
=MIN(SI(FREQUENCE(EXACT($O11:$DG11<>"p";COLONNE($O11:$DG11));EXACT($O11:$DG11="p";COLONNE($O11:$DG11)))<>0;FREQUENCE(EXACT($O11:$DG11<>"p";COLONNE($O11:$DG11));EXACT($O11:$DG11="p";COLONNE($O11:$DG11)))))
mais ca me retourne 0.
Si qqn a une solution, merci par avance
ex concret /si une lettre par cellule
si : wwwwpppppppppaaaaaappeeepzzzzzppp avec la premiere formule j'ai bien le bon resultat (=3, les "e")
mais si: wwwwpppppppppaaaaaappPPPpzzzzzppp dans ce cas la premiere formule vas me dire (=4,les"w" et ne va prendre les "P". et mon autre formule avec exact me retourne "0".
je sais pas si mon exemple ne complique pas les choses ....
Bonjour,
Chez moi, avec LibreOffice Calc, la formule fonctionne correctement (avec p minuscule) dans les 2 cas.
Y a t-il une option dans Excel pour le respect de la casse pour les critères = et <> ? (il y en a une dans Calc).
Si ce n'est pas possible, tu peux utiliser la fonction CODE pour différencier "p" et "P" :
=MIN(SI(FREQUENCE(SI(CODE($O24:$DG24)<>112;COLONNE($O24:$DG24));SI(CODE($O24:$DG24)=112;COLONNE($O24:$DG24)))<>0;FREQUENCE(SI(CODE($O24:$DG24)<>112;COLONNE($O24:$DG24));SI(CODE($O24:$DG24)=112;COLONNE($O24:$DG24)))))Sinon concernant la fonction EXACT, tu n'as pas la bonne syntaxe.
Je n'ai pas testé si cette fonction marche en matriciel (pas le temps) mais la syntaxe a utiliser devrait être :
Remplacer :
$O24:$DG24="p" par EXACT($O24:$DG24;"p")
et
$O24:$DG24<>"p" par NON(EXACT($O24:$DG24;"p"))
dans ta première formule.
A+
Bonjour,
Non je ne trouve pas comment respecter directement la casse ds excel.
j'ai essayé avec le code (..........112) et en remplacant $O24:$DG24="p" par EXACT($O24:$DG24;"p")
et
$O24:$DG24<>"p" par NON(EXACT($O24:$DG24;"p"))
et je trouve en resultat #N/A
Si qqn a une solution...
Bonjour alfidx!
À moi de vous sauver encore!
=MIN(SI(FREQUENCE(SI(NON(EXACT($O24:$DG24;"p"));COLONNE($O24:$DG24));SI(EXACT($O24:$DG24;"p");COLONNE($O24:$DG24)))<>0;FREQUENCE(SI(NON(EXACT($O24:$DG24;"p"));COLONNE($O24:$DG24));SI(EXACT($O24:$DG24;"p");COLONNE($O24:$DG24)))))
Ça marche pour moi !
Cordialement
Bonjour Xor,
Je viens de me rendre compte que j'avais oublié de te mettre le post en résolu.
J'en profite pour te remercier de ta disponibilité pour moi.
J'ai utilisé tes fonctions, j'obtiens ce que je cherchais .
Bonne fin de journée
alfidx
Et à toi, alfidx.
Heureux de t'avoir aidé.
Bonne journée.