Boucle suppression colonnes

Bonjour,

Pouvez-vous m'aider quant à l'écriture d'une boucle qui détecte les intitulés "open", "high", "low", "close", "volume" pour les supprimer par la suite. La difficulté réside dans le fait que le nombre de ces intitulés est variable.

Ci-joint, vous trouverez ma feuille Excel contenant les données susmentionnées

Merci par avance de votre aide !

Student

Bonjour,

Une solution avec la méthode Find

Sub TrouverCel()
Dim Tablo
Dim Plage As Range, C As Range
Dim i As Integer
Dim firstAddress As String
    Tablo = Array("open", "high", "low", "close", "volume")
    With Worksheets("Feuil1")
        Set Plage = Range(.Cells(2, 1), .Cells(2, .Cells(2, Columns.Count).End(xlToLeft).Column))
        For i = 0 To UBound(Tablo)
            Set C = Plage.Find(Tablo(i), , xlValues, xlWhole)
            If Not C Is Nothing Then
                firstAddress = C.Address
                Do
                    C.Interior.ColorIndex = 3
                    Set C = Plage.FindNext(C)
                Loop While Not C Is Nothing And C.Address <> firstAddress
            End If
        Next i
        Set Plage = Nothing: Set C = Nothing
    End With
End Sub

A+

Salut,

Merci pour ta réponse mais au lieu de souligner les cellules en rouge, j'aimerai les supprimer ...

Allons-y pour l'éradication.

Sub SupprimerCel()
Dim Tablo
Dim Plage As Range, C As Range
Dim i As Integer
    Tablo = Array("open", "high", "low", "close", "volume")
    Application.ScreenUpdating = False
    With Worksheets("Feuil1")
        Set Plage = Range(.Cells(2, 1), .Cells(2, .Cells(2, Columns.Count).End(xlToLeft).Column))
        For i = 0 To UBound(Tablo)
            Set C = Plage.Find(Tablo(i), , xlValues, xlWhole)
            Do While Not C Is Nothing
                C.EntireColumn.Delete Shift:=xlToLeft
                Set C = Plage.Find(Tablo(i), , xlValues, xlWhole)
            Loop
        Next i
        Set Plage = Nothing: Set C = Nothing
    End With
End Sub

A+

Genial merci beaucoup !!!