Somme prod pour cumuler un critère OU un autre
Bonjour,
Je fais des formules pour dénombrer des lignes qui cumulent plusieurs critères.
Je sais utiliser la somme prod pour le faire.
Mais là, je dois dénombrer des lignes avec plusieurs critères puis un critère ou un autre.
En gros 3 critères + une colonne qui doit être soit vide, soit une date > à une autre date définie.
Le OU me renvoie à Vrai ou Faux, donc ça ne va pas pas avec ma formule Somme prod.
Et avec un SI, je ne sais pas ce que je peux écrire...
Quelqu'un peut-il m'aider ?
D'habitude je trouve toujours mes réponses sur les forums directement, sans avoir à poser de question, mais là je n'arrive pas à bien formuler ma question pour trouver la réponse...
Merci d'avance, et dîtes moi si ce n'est pas clair !
Anne-Sophie
Bonsoir,
tu ne peux pas utiliser ET ou OU dans sommeprod(), mais :
* = ET
+ = OU
Donc:
=SOMMEPROD(((B2:B8="")+(B2:B8=1))*(C2:C8=1))
eric
Merci !
C'est parfait !
Je ne connaissais pas ce +.
Encore un grand merci !
bonsoir eriiic
il me semble , de memoire que sur les versions recentes xl on peux utiliser le \ pour ou ; cela vient de MYTA si Nad vois ce post
elle nous en dira plus car je n'ai plus la syntaxe exacte ; du fait qu'elle proscrite pour mon vieil xl 2000
wait and see
cordialement
Bonjour,
tulipe_4 a écrit :il me semble , de memoire que sur les versions recentes xl on peux utiliser le \ pour ou ; cela vient de MYTA si Nad vois ce post
elle nous en dira plus car je n'ai plus la syntaxe exacte ; du fait qu'elle proscrite pour mon vieil xl 2000
wait and see
Il s'agit là de l'utilisation de constantes matricielles.
=SOMMEPROD(((B2:B8="A")+(B2:B8="B"))*(2:C8) peut s'écrire =SOMMEPROD((B2:B8={"A"."B"})*C2:C8)
Pour une plage en colonne (comme ci-dessus) on utilise le . (point) si le séparateur décimal est la virgule (version FR de Excel entre autre), ou \ (anti-slash) si le séparateur décimal est le point (version US).
Si la plage de données est en ligne (A2:G2 à la place de B2:B8 par exemple) on utilise alors le ; (point-virgule) en version FR et je crois (à vérifier) la virgule en version US.
On peut aussi mettre les critères A et B dans des cellules.
Avec A en D1 et B en F1,
=SOMMEPROD((B2:B8={"A"."B"})*C2:C8) devient =SOMMEPROD((B2:B8=D1:F1)*C2:C8)
La zone de critère doit être "perpendiculaire" à la zone ou s'applique ces critères.
Si on a A2:G2 à la place de B2:B8 par exemple, cela donne :
=SOMMEPROD((A2:G2={"A";"B"})*A3:G3) devient =SOMMEPROD((A2:G2=H1:H2)*A3:G3)
Simplement :
Zone de recherche en colonne → zone de critère en ligne,
Zone de recherche en ligne → zone de critère en colonne.
A+
merci oooiste
c'est toujours utile de rappeler l'utilisation de signes autres que * + - = ...... car il est vrai que souvant cela simplifie les choses ;le tout est de connaitre l" astuce" ; l'aide ou autre ne sont pas eloquents sur ça ; il faut etre dedans ou ,vraiment s'interesser a xl pour connaitre l'existance de ces cas de figure
crdialement