Chercher une valeur dans une Colonne et Supprimer Ligne Enti

Bonjour, j'aimerai chercher une valeur dans une feuille et puis supprimer les lignes entières quand ils y figurent

Voici mon code, je ne comprend pas ce qui ne fonctionne pas

nomMedecin = Split(ActiveCell, vbLf)(0)
        MsgBox nomMedecin 'jusque là pas de souci le MsgBox c'est bien la cellule que je souhaite
        Sheets("Rendezvous").Select

        Dim i As Integer

        For i = 4 To 20 'je vais aller de la 4e ligne, 1° colonne à la 20e ligne, 1° Colonne
            If Cells(i, 1).Value = nomMedecin Then Cells(i, 1).EntireRow.Delete
        Next i

Merci de m'éclairer ! Je trouve pas ce qui ne fonctionne pas !

Bonjour

Arancino a écrit :

je ne comprend pas ce qui ne fonctionne pas

Il faut être plus précis : Message d'erreur ? n'efface pas les lignes ? etc...

Ensuite pour effacer de ligne (le plus pratique) c'est de commencer à la fin et remonter

Changes

For i = 4 To 20 'je vais aller de la 4e ligne, 1° colonne à la 20e ligne, 1° Colonne

Par

For i = 20 To 4 Step -1      'je vais aller de la 20e ligne, 1° colonne à la 4e ligne, 1° Colonne

Comme i contient le numéro de ligne tu peux simplifier

If Cells(i, 1).Value = nomMedecin Then Cells(i, 1).EntireRow.Delete

Par

If Cells(i, 1).Value = nomMedecin Then Rows(i).Delete

Cela devrait fonctionner

Sinon joins ton fichier

Coucou Banzai.

Merci encore pour ton aide qui m'est précieuse.

Cependant celà ne fonctionne pas !

Je joint mon fichier

Bonjour

Je pense avoir compris

Tu ne peux pas en étant dans le module d'une page (Planning) travailler directement sur des cellules d'une autre page (même en changeant de page) en les nommant juste sans préciser la feuille dans laquelle elles sont

il aurait fallut marquer

If Sheets("Rendezvous").Cells(i, 1).Value = nomMedecin Then Sheets("Rendezvous").Rows(i).Delete

Attention dans ce code pour que cela fonctionne j'ai remplacé vbLf par VbCr , car le Cr est avant le Lf

Modifies ta macro

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim nomMedecin As String
Dim i As Integer

  If ActiveCell = "" Then
    If Target.Count > 1 Then Exit Sub
    ' On vérifie d'abord si c'est la coupure
    If Not Intersect(Target, Range("C13:E14")) Is Nothing Then
      Cancel = True
      MsgBox ("Les médecins sont en pause !")
    ElseIf Not Intersect(Target, Range("C5:E25")) Is Nothing Then
      Cancel = True
      UserForm1.Show False
    End If
  Else
    Cancel = True
    nomMedecin = Split(ActiveCell, vbCr)(0)
    MsgBox nomMedecin
    With Sheets("Rendezvous")
      For i = 20 To 4 Step -1
        If .Cells(i, 1).Value = nomMedecin Then .Rows(i).Delete
      Next i
    End With
    ActiveCell = ""
    ActiveCell.Interior.ColorIndex = 0
  End If
End Sub

Merci Banzai64 !

J'aurais jamais trouvé tout seul !

Sujet résolu