Taux de rejet par mois
Bonjour,
Je voudrai calculer le taux de rejet par mois.
Pour cela, j'ai 2 colonnes, une avec la date et une avec rejet oui ou non.
Je souhaite que le taux de rejet se calcule automatiquement dés que j'ajoute une ligne.
Pouvez vous m'aider?
Merci
Ci joint un tableau exemple.
Salut le forum
Regarde avec DECALER pour créer une plage dynamique
Mytå
Allo Myta,
D'abbord, merci pour ton aide...
Je suis pas sur de comprendre mais pour moi, la fonction décaler ne me permet pas de reconnaitre le mois indiqué dans la 1er colonne.
Ces mois sont parfois mélangés.
Je cherche une formule du type =SUM(IF($a$5:$a$1955>0;IF(MONTH($a$5:$a$1955)=MONTH(d5);$b$5:$b$1955))) mais quand je modifie avec un "countif", j'ai un messages d'erreur comme quoi je mets trop d'argument
(=countif(IF($a$5:$a$1955>0;IF(MONTH($a$5:$a$1955)=MONTH(d5);$b$5:$b$1955;"o")))
Bonsoir,
=SUMPRODUCT((MONTH(A$5:A$49)=MONTH(D11))*(B$5:B$49="o"))/SUMPRODUCT(MONTH(A$5:A$49)=MONTH(D11))A+
Merci OOoiste,
J'ai supprimé la 2eme partie (apres le /) et je calcule le nombre de rejet et le nombre de first pass pour calculer mon tx.
Peux tu m'expliquer l'usage des * et / dans ce genre de formule?
Merci a tous pour votre aide
La première partie calcule le nombre de "o" pour le mois,
la deuxième le total de "o" et "n".
Puisque tu voulais calculer le taux de rejet, j'avais donc divisé le premier par le second.
Concernant la formule SUMPRODUCT :
MONTH(A$5:A$49)=MONTH(D11) renvoie une matrice de VRAI ou FAUX suivant si la condition est vérifiée ou non.
idem pour B$5:B$49="o"
SUMPRODUCT fait le produit scalaire des 2 matrices (la somme des produits de chaque élément des 2 matrices)
La formule pourrait alors être =SUMPRODUCT(MONTH(A$5:A$49)=MONTH(D11);B$5:B$49="o") mais Excel
(à contrario de LibreOffice et OOo) nécessite de transformer ces VRAI et FAUX en 1 et 0.
On peut alors utiliser N() comme ceci : =SUMPRODUCT(N(MONTH(A$5:A$49)=MONTH(D11));N(B$5:B$49="o"))
ou changer 2 fois le signe --1=+1 → =SUMPRODUCT(--(MONTH(A$5:A$49)=MONTH(D11));--(B$5:B$49="o"))
ou multiplier par 1 → =SUMPRODUCT(1*(MONTH(A$5:A$49)=MONTH(D11));1*(B$5:B$49="o"))
Ou enfin multiplier les 2 matrices (ce que j'ai fait).
A+
Merci pour ton explication, c'est compliqué mais très clair.
Grand merci pour ton aide!!!