Formule SOMMEPROD
bonjour le forum,
j'essaie de comprendre:
=SOMMEPROD(($D$13:$D$198<>"")*($AF$13:$AF$198<>6700)*
($P$13:$P$198="MME")*1+($P$13:$P$198="MLLE")*($AQ$13:$AQ$198>17)*
($AQ$13:$AQ$198<36))
cette formule est-elle bonne sachant que j'ai un soucis avec le "compris entre 17 et 36", je ne suis pas sur de moi !! (surtout que le resultat est faux)
merci de votre aide
Bonsoir,
PAs simple sans un fichier. Tu cherches quoi exactement ? Un nbre de valeur ? un montant total ?
Sinon peut être comme ceci -> =SOMMEPROD((($D$13:$D$198<>"")*($AF$13:$AF$198<>6700)*($P$13:$P$198="MME")*1)+(($P$13:$P$198="MLLE")*($AQ$13:$AQ$198>17)*($AQ$13:$AQ$198<36))*1)
A te lire
Dan
Bonsoir, salut Dan,
Il me semble que c'est le second test sur une valeur texte qui devrait aussi être rendu numérique.
=SOMMEPROD(($D$13:$D$198<>"")*($AF$13:$AF$198<>6700)*(($P$13:$P$198="MME")*1)+(($P$13:$P$198="MLLE")*1)*($AQ$13:$AQ$198>17)*($AQ$13:$AQ$198<36))
Avec un petit fichier on aurait pu tester !
dré
Re,
effectivement Dre, j'avais effectué un test sur une partie de la formule -->
=SOMMEPROD((($P$13:$P$198="MLLE")+($AQ$13:$AQ$198>17)*($AQ$13:$AQ$198<36))*1)
ou
=SOMMEPROD((($P$13:$P$198="MLLE")*1)+($AQ$13:$AQ$198>17)*($AQ$13:$AQ$198<36))
A voir avec notre forumeur...
Dan
merci mais je suis pas bon en résultat.
Voici l'objectif:
. compter le nombre de "MME" et de "MLLE" dans la colonne P
- -> dont les chiffres sont > à17 et < à36 dans la colonne AQ (compris entre 17 et 36)
- --> à condition d'avoir 6700 dans la colonne AF
- --> si la colonne D est renseignée.
facile non! :wink: pour vous....
(mon problème c'est que j'ai 2 fois 2 conditions MME+MLLE et >17et<36)
pour compléter mon explication, voici ce que j'ai fais dans un autre cas:
compter le nombre de "M" dans la colonne P
- -> dont les chiffres sont < à18 dans la colonne AQ
- --> à condition d'avoir 6700 dans la colonne AF
- --> si la colonne D est renseignée.
=SOMMEPROD(($D$13:$D$198<>"")*($AF$13:$AF$198=6700)*
($P$13:$P$198="M")*($AQ$13:$AQ$198<18))
NB: a la place du 8, j'ai une binette qui s'affiche en prévisualisation)
----> vous me direz si c'est bon.
merci à vous
édité par Amadéus pour désactivation des smilies
Re,
=SOMMEPROD((($D$13:$D$198<>"")*($AF$13:$AF$198<>6700)*($P$13:$P$198="MME")*1)+(($P$13:$P$198="MLLE")*($Q$13:$Q$198>17)*($Q$13:$Q$198<36)*1))
Amicalement
Dan
Yo,
g bcp essayé mais c pas bon, alors g fait ça:
=SOMMEPROD(($D$13:$D$198<>"")*($AF$13:$AF$198=6700)*(($P$13:$P$198="MME")+($P$13:$P$198="MLLE"))*(($AQ$13:$AQ$198>17)*($AQ$13:$AQ$198<36)))
car il me faut:
. compter le nombre de "MME" et de "MLLE" dans la colonne P (donc: MME+MLLE)
- -> dont les chiffres sont compris entre 17 et 36 dans la colonne AQ (compris entre 17 et 36)
- --> à condition d'avoir 6700 dans la colonne AF --> donc la je suppose qu'il fallait mettre =6700
- --> si la colonne D est renseignée.
Merci de me dire si ma formule est bonne selon vous.
une fois merci
Bonjour
Si tu as testé ta formule, tu as du voir qu'elle est bonne.
En voici une autre si ta colonne P contient M, MME,MLLE.
=SOMMEPROD((EXACT(DROITE(P13:P198;1);"E")*1)*($D$13:$D$198<>"")*(AF13:AF198=6700)*($AQ$13:$AQ$198>17)*($AQ$13:$AQ$198<36))
Cordialement
Merci,
C'est vrai ce que tu dis mais ya des trucs que j'comprend pas:
Dans ma formule g une différence de 1 et j'vois pas pquoi !!
Je viens d'essayer celle que tu me donnes (car effectivement g M MME MLLE) et g 1 en résultat alors que je devrais avoir 9 !
Tu coomprends que j'ai des doutes. je vois pas l'erreur et g verifié mes cellules et ça ne recoupes pas d'autres résultats !!!
voila pquoi je cherche chez les forts comme vous.
merci bcp pour ton aide
Ah!
Amadeus, toutes mes excuses, ta formule est bonne car elle ne compte que les "E" de MME et MLLE.
je viens de m'en rendre compte av plusieurs essais.
Par contre moi g tjs mon ecart
mer mille fois et encore pardon
Re bonsoir
Tu est tout pardonné.
Par contre, pour ton 1 d'écart, il est difficile de savoir ce qui ne va pas sans avoir comme toi le fichier sous les yeux. S'il n'est pas confidentiel, tu pourrai l'envoyer. Regarde joindre un fichier, en haut de cette page.
Pour chercher ton erreur, une première piste est de savoir si tu saisis M,MME et MLLE en tapant chaque fois le texte ou si tu utilise une liste de validation, car, su tapes à chaque fois le texte, tu peux inclure un espace avant MME ou MLLE et Excel ne prendra pas cette ligne en compte (Je dis avant, car si c'était après, c'est ma formule qui donnerait un résultat erronné.)
Cordialement