Problème de récupération d'infos
Bonjour,
Un nouveau problème vient à moi:
https://www.excel-pratique.com/~files/doc/E3rsTtest.xls
Voici la formule que j'ai utilisé:
=SI(A:A="BESNAULT";NB.SI(G:G;"13");"FAKE")
Mais ça ne fonctionne pas.
Je voudrai en fait le nombre de fois que BESNAULT a parlé du département 13
Voilà.
Bonjour
=SOMMEPROD(((A1:A5="BESNAULT")*1)*((GAUCHE(G1:G5;2)*1=13)*1))
Cordialement
En fait si je suis sur la même feuille tout fonctionne correctement, mais si je suis sur une feuille différente ça me donne un #REF! est-ce normal ?
Bonjour,
Si cela doit focntionner mais il faut mettre tes références de la feuille d'où tu vas prendre l'info.
Exemple si la formule se trouve en feuille 1 --> =SOMMEPROD(((Feuil1!A1:A5="BESNAULT")*1)*((GAUCHE(Feuil1!G1:G5;2)*1=13)*1))
Fais un couper - coller vers la feuille en question.
Amicalement
Dan
Bonjour, salut Amadeus et Dan,
On dirait qu'il y a déjà les soldes (→ le nombre de *1)
=SOMMEPROD((A1:A5="BESNAULT")*(GAUCHE(G1:G5;2)="13"))
fonctionne aussi.
Pour afficher FAKE quand le résultat est égal à 0 (pas possible, à ma connaissance, avec un SOMMEPROD) :
Format personnalisé : [=0]"FAKE";Standard
dré
Ma fonction est la suivante:
=SOMMEPROD(((Données!C8:C4907="BESNAULT")*1)*((GAUCHE(Données!I8:I4907;2)*1=13)*1))
Et l'erreur est la suivante:
#VALEUR!
Je ne comprend pas...
Re,
La fonction GAUCHE renvoie du texte.
Essaie en mettant des "" à "13"
Si cela ne fonctionne pas, un petit extrait de ton fichier sera plus facile pour repérer l'erreur.
dré
Si je ne met pas 13 ça ne retournera pas le nombre de fois que BESNAULT a traité le Département 13 si ?
Non, cela te retournera le nombre de fois qu'il y a "BESNAULT", puisque la deuxième condition n'en est pas une.
Mets un nouvel exemple en pièce jointe avec le problème, ce sera plus facile pour t'aider.
dré
https://www.excel-pratique.com/~files/doc/2WtSatest.xls
Voilà le fichier en bcp plus petit ^^'
J'ai mis la fonction en colonne DS sans le "13" mais avec ""
Re,
Il faut faire référence aux bonnes colonnes : B et H et non C et I
Il faut supprimer les *1 et mettre le nombre entre ''"
Et tout fonctionne.
Il n'y a que Joindre un fichier qui ne fonctionne pas !
Voici la formule à mettre en DS4 :
=SOMMEPROD(($B$4:$B$4907="BESNAULT")*(GAUCHE($H4:$H$4907;2)="13"))
dré
Bonjour
Le problème vient des lignes vides, voici la formule
=SOMMEPROD((($B$4:$B$4907="BESNAULT")*1)*(EXACT(GAUCHE($H$4:$H$4907;2);"13")))
Cordialement
PS: Pile poil ensemble, Bonjour Dré
Salut Amadeus,
Toujours les soldes ?
Sans EXACT cela fonctionne aussi :
https://www.excel-pratique.com/~files/doc/T2ap8KiBa.xls
A ma connaissance, la fonction EXACT ne sert qu'à différencier les minuscules des majuscules.
dré
Salut Dré
c'est quand même plus joli, et ça marche quand même!
Je blague, mais je cherchais à contourner mon erreur du GAUCHE*1 qui me plantait sur les cellules vides et je n'ai pas trop réfléchi.
Cordialement
Merci bcp à vous ^^' vous m'aidez énormément dans le développement de mon InfoCentre qui au fur et à mesure des jours devient de plus en plus gros et de plus en plus difficile à segmenter avec des requêtes. Merci !
J'ai une autre petite question, sur une de mes cellules j'ai cette fonction:
=SOMMEPROD((EXACT(GAUCHE(Données!I8:I14306;2);"20")*((Données!BZ8:BZ14306="Visite")*1)))
J'aimerai adapter le nom du correspondant dedans. J'ai donc essayé ça:
=SOMMEPROD(((Données!$C$4:$C$15000="BESNAULT")*1))*((EXACT(GAUCHE(Données!$I$4:$I$15000;2);"39")*((Données!$BZ$4:$BZ$15000="Visite")*1)))
Mais ça me retourne la valeur 0
Quelqu'un peut me préciser mon erreur ?
Bonjour,
Comme je n'ai pas le fichier "Données", je n'ai pas pu vérifier.
Essaie ceci :
=SOMMEPROD((Données!$C$4:$C$15000="BESNAULT")*(GAUCHE(Données!$I$4:$I$15000;2)="39")*(Données!$BZ$4:$BZ$15000="Visite"))
L'erreur était un ; au lieu d'un =
J'en ai profité pour quelque peu simplifier cette formule.
dré
Ca marche impeccablement bien, merci à toi dre !