Recherche Formule

bonjour a tous

je suis assez novice dans excel , je voudrais mettre des "P" en automatique dans des cellules d'une ligne par rapport la la plage donné dans la cellule A

Merci d'avance de vos retour

Bonjour,

Une proposition à entrer en B2 puis tirer vers la droite et le bas :

=SI(ET(CNUM(B$1)-CNUM(GAUCHE($A2;TROUVE("-";$A2)))>=0;001;CNUM(B$1)-CNUM(DROITE($A2;TROUVE("-";$A2)-1))<=0;001);"P";"")

Super je vais essayer dans mon vrai fichier

encore merci pour votre retour

Bonne journée

Salut,

Une autre proposition rejoignant ce qu'a fait saboh12617 :

=SI(CNUM(B$6)>=CNUM(GAUCHE($A7;5));SI(CNUM(B$6)<=CNUM(DROITE($A7;5));"P";"");"")

bonjour

une proposition avec des explications

cordialement

Théo123 a écrit :

Salut,

Une autre proposition rejoignant ce qu'a fait saboh12617 :

=SI(CNUM(B$6)>=CNUM(GAUCHE($A7;5));SI(CNUM(B$6)<=CNUM(DROITE($A7;5));"P";"");"")

Bonjour à tous de nouveau,

@Théo : attention, je ne sais pas pourquoi mais j'ai remarqué que dans le fichier d'exemple cette évaluation CNUM(B$6)<=CNUM(DROITE($A7;5)) était parfois erronée, sans doute à cause d'un problème de précision interne à Excel.

C'est pourquoi je suis passé par une soustraction et un seuil de précision de 0.001, car autrement j'avais, dans le cas de la 1e ligne par exemple, le créneau 6h30 qui sautait.

Salut de nouveau,

En entrant dans la cellule du bas.

Bonjour a tous

j'aurais une autre complexité a rajoute dans mon fichier et je voudrais je voudrais que sa mets soit le P ou F selon ce qui est mentionné dans la nouvel colonne B en plus de la colonne A

Rebonjour,

Simplement remplacer le "P" de la formule par la cellule en question. Idem pour la formule de Théo.

=SI(
  ET(
    CNUM(B$1)-CNUM(GAUCHE($A2;TROUVE("-";$A2)))>=0;001;
    CNUM(B$1)-CNUM(DROITE($A2;TROUVE("-";$A2)-1))<=0;001
  );
  $B2;
  ""
)

Re bonjour

déjà merci pour le temps passer pour ma formule ; par contre a partir de la ligne 2 je me retrouve décaler d'une case

bonjour le fil,

un autre essai (et avec 1 ligne + 1 colonne supplémentaire encore plus facile)

=SI(ET(GAUCHE($A2;5)<=TEXTE(C$1;MonFormat);TEXTE(C$1;MonFormat)<=STXT($A2;7;5));$B2;"")

bonjour BsAlv ,

je suis un peu perdu avec votre formule qui ma l'air bien, car quand j'exporte la formule sur mon fichier final cela ne fonctionne pas surement dû a "MonFormat" , je rappelle que je suis novice sur Excel

cordialement

re,

c'est parce que ma version Excel n'est pas francophone ..., replacer le "monformat" par "hh:mm"

=SI(ET(GAUCHE($A2;5)<=TEXTE(C$1;"hh:mm");TEXTE(C$1;"hh:mm")<=STXT($A2;7;5));$B2;"")

Bonjour à tous, juste pour corriger ma proposition :

=SI(
  ET( ARRONDI(CNUM(C$1);4)-ARRONDI(CNUM(GAUCHE($A2;TROUVE("-";$A2)));4)>=0;
      ARRONDI(CNUM(C$1);4)-ARRONDI(CNUM(DROITE($A2;TROUVE("-";$A2)-1));4)<=0);
  $B2; ""
)

Ci-joint MAJ.

@saboh12617, tout petit détail,

si tu utilise des arrondis, c'est mieux d'itiliser =ARRONDI.AU.MULTIPLE(.../1440) au lieu de ARRONDI(CNUM(...);4).

Voir PJ, feuille "Blad1"). Il y a 1440 minutes dans une journée et 70 des 1440 donnent une fausse arrondi (de 9 secondes) dont heureusement aucune exactement à un multiple de 10 minutes (144 moments, pourtant la probabilité était 144*70/1440=7). En flamand, il y a un dicton "il n'est pas nécessaire d'être belle pour avoir de la chance, mais cela aide". Donc ma question est : est-tu beau ou as-tu eu de la chance ?(ou ma théorie, est-elle fausse)

Salut Bart,

Oui ta remarque est intéressante.

J'ai procédé comme ceci : 1 minute ≈ 0,00069 (je n'ai pas pensé à arrondir au multiple d'une minute, j'ai pris un peu de marge). Donc je me suis dit qu'en faisant l'arrondi à 1E-4 (0,0007) on n'aura pas de problème de superposition car la prochaine minute est trop distante (2 min ≈ 0,00139 => 0,0014 <> 0,0007). Ce qui compte dans mon raisonnement c'est de comparer les 2 arrondis, qu'ils soient égaux à la valeur réelle ou non n'a pas d'importance. C'est un filtre.

La précision voulue par l'OP étant à priori sur des plages de 10 min, ma formulation est, il me semble, précise à la minute donc ok. Après oui, si on s'amuse à rentrer des temps avec des secondes, ça risque de casser : c'est la limite. Problème a priori hors sujet donc je ne l'ai pas traité (dans ce cas ta proposition casse aussi).

Quant au fait que je sois beau, ma maman me l'a toujours affirmé (le plus beau même ).

bonjour

d'ou l'intérêt de passer par

ENT( le temps*1000) voire 10000

cordialement