Formule de recherche renvoyant plusieurs données séparées par un
Bonjour,
J'ai aujourd'hui besoin de vos lumières pour créer une formule de recherche renvoyant plusieurs donnés séparées par un - dans une seule cellule.
Exemple: dans une base de données, j'ai 3 lignes d'une clé a qui renvoie vers 3 documents (x, y et z) + 3 dates. Je dois pouvoir indiquer dans une seule cellule que a = x-y-z (idem pour les dates).
Merci beaucoup pour votre aide.
Bonjour,
Avec 3 formules simples uniques :
en G3 : =UNIQUE(A2:A10) (formule unique)
en H3 : =JOINDRE.TEXTE("-";;FILTRE($B$2:$B$10;$A$2:$A$10=$G10)) (formule à recopier)
en I3 : =JOINDRE.TEXTE("-";;TEXTE(FILTRE($C$2:$C$10;$A$2:$A$10=$G10);"jj/mm/aaaa")) (formule à recopier)
Qu'on peut éventuellement assembler pour n'en faire qu'une seule.
ou aussi avec une autre approche :
=SUBSTITUE(GROUPER.PAR(A2:A10;ASSEMB.H(B2:B10;TEXTE(C2:C10;"jj/mm/aaaa"));TABLEAU.EN.TEXTE;;0);";";"-") (formule unique)
Top, merci.
Bonjour,
Je rouvre le topic car j'ai une demande un peu similaire.
La cible ici est la colonne B.
En colonne A, j'ai des caractères. Je dois les chercher en colonne E (il peuvent être dissimulés avec d'autres caractères dans la cellule).
Une fois A retrouvé en E, je dois pouvoir renvoyer F en B.
Auriez-vous svp une solution?
Bonjour,
À essayer en B3 :
=FILTRE($F$2:$F$3;REGEX.TEST($E$2:$E$3;A2);"")ou aussi :
=RECHERCHEX(A2;$E$2:$E$3;$F$2:$F$3;"";3)Bonjour à tous !
Une proposition, type formule unique dynamique en F3 (Attention à la nécessaire propagation...
=MAP(E2:.E10;LAMBDA(x;UNIQUE(FILTRE(B2:B4;REGEX.TEST(x;A2:A4;1);""))))Remarques :
- L'argument de la fonction REGEX traitant de la casse a été réglé sur 1 (à modifier si besoin est).
- Quid des valeurs cherchées retournant des éléments distincts ? Faut-il créer une liste ?
Bonjour à vous,
@BeGood => les formules proposées ne fonctionnent malheureusement pas.
@JFL J'ai en effet PROPAGATION qui apparaît, comment contrer?
Pas nécessaire de faire une liste, partir du principe qu'on ne retrouvera la valeur qu'une seule fois dans la liste.
Bonjour à tous de nouveau !
@JFL J'ai en effet PROPAGATION qui apparaît, comment contrer?
Une telle formule nécessite qu'elle puisse se propager. Si elle ne dispose pas de cette place, elle retourne cette erreur.
Donc :
- Prévoir assez de place (vide...) en dessous
- Supprimer les saisies manuelles (ou autre formule) de la zone.
Si le souci persiste, joignez un classeur représentatif.
Bonjour à tous,
Précisez ce qui ne fonctionne pas.
Peut-être un souci avec votre version M365 qui ne supporte pas (encore) les Regex ?
Essayez aussi :
=SIERREUR(INDEX($F$2:$F$3;EQUIVX(VRAI;ESTNUM(CHERCHE(A2;$E$2:$E$3))));"")Ou joignez votre fichier avec les formules qui ne fonctionnent pas
Top, fonctionne, merci!
Bonsoir à tous !
Ma compréhension était, à l'évidence, erronée....
Proposition dynamique corrigée :
=MAP(A2:.A10;LAMBDA(x;FILTRE(F2:F3;REGEX.TEST(E2:E3;x;1);"")))