Zéro et cellule vide différents

Bonjour à tous. J’utilise la formule RechercheV pour afficher les notes de mon tableau. Mais dans le tableau si l’élève n’a pas composé, la cellule concernée est vide. Il aussi peut composer mais avoir la note 0, ce qui est diffèrent car au moment du calcul de la moyenne les cellules vides ne sont pas prises en compte.

Le problème est le résultat du recherche qui ne fais pas la distinction entre l’élève qui n’as pas composé et celui qui a eu 0. (Le résultat est pour tous les deux cas 0).

Je voudrais une solution pour résoudre cela au niveau de la formule.

Merci par avance

Bonjour,

Remplacez la formule de recherche par

=SI(RECHERCHEV(E6;Tableau1;2;0)="";"";RECHERCHEV(E6;Tableau1;2;0))

Il faut vérifier le résultat, sinon il est automatiquement converti en nombre.

Bonjour à tous !

Une approche légèrement différente :

=SIERREUR(RECHERCHEV(E6;Tableau1&"";2;0)* 1;"")

bonjour

pour la moyenne

=SOMME(Tableau1[@[Anglais]:[Histoire]])/NB.SI(Tableau1[@[Anglais]:[Histoire]];"<>")

pour la recherche

=SI(ESTVIDE(DECALER(Tableau1[[#En-têtes];[Nom]];EQUIV(Recherche!E6;Tableau1[Nom];0);EQUIV(Recherche!D9;Tableau1[[#En-têtes];[Anglais]:[Moyenne]];0);;));"pas de resultat";DECALER(Tableau1[[#En-têtes];[Nom]];EQUIV(Recherche!E6;Tableau1[Nom];0);EQUIV(Recherche!D9;Tableau1[[#En-têtes];[Anglais]:[Moyenne]];0);;))

cordialement

Bonjour à tous de nouveau !

Et pour une recherche dynamique (liée à la matière) :

=SIERREUR(RECHERCHEV(E6;Tableau1&"";EQUIV(D9;Tableau1[#En-têtes];0);0)* 1;"")

Bonsoir

Merci grandement à tous pour les réponses qui sont toutes cool..

Bonsoir à tous !

Bien...

Je vous remercie de ce retour.

------> Ne pas oublier de passer le sujet en mode résolu !