Répertorier des nombres
Bonsoir à tous,
Je suis à la recherche d' une formule. Pardon pour le titre flou.
Regardez mon fichier joint svp.
A partir de la plage B1 - AA8 je voudrais arriver au résultat inscrit dans la plage B12 - j27.
Comment arriver à ce résultat? ..... c' est simple.
Dans la plage B1 - AA8 il y a des nombres dans les colonnes jaunes ( ces nombres ont parfois des doublons), en face de ces nombres il y a d' autres nombres dans les colonnes bleues.
Mon but est de regrouper dans une seule colonne tous les nombres des colonnes jaunes mais sans les doublons , et d' associer a chacun de ces nombres le nombre qui leur est associé en colonne bleue. Pour une bonne compréhension regardez le résultat dans la plage B12 - j27.
Je vous remercie d' avance pour votre aide
Bonjour,
Ci-joint une proposition en réorganisant votre tableau. On ne peut pas travailler correctement avec toutes les données collées les unes sur les autres. Il vaut mieux les aligner quand elles représentent la meme grandeur, les formules fonctionnent beaucoup mieux ainsi.
Une fois le tableau “déplié”, il suffit d’utiliser UNIQUE et FILTRE pour obtenir le résultat demandé.
Bonsoir Saboh12617, c' est parfait car c' est le résultat auquel je voulais arriver donc même si ça m' oblige à désorganiser le tableau ce n' est pas grave du tout.
Merci beaucoup pour votre aide
Bonne soirée
Bonjour Tulipe, Olivier,
Top si le sujet est résolu.
Tulipe impressionnant. Je me doutais qu’il y avait manière à traiter le sujet en 1 étape (surement plus facilement avec O365 d’ailleurs), mais au vu de la simplicité d’une approche organisée je me suis laissé tenter…
Beau travail cependant
Bonjour Tulipe 4 , merci beaucoup pour votre aide, je vois la réponse que maintenant, je suis désolé
Bonjour à tous !
Pour le "fun", avec M365, formule unique et dynamique :
=LET(
p; ORGA.LIGNES(DANSCOL(B1:AA8); 2);
n; PRENDRE(p; ; 1);
u; TRIER(UNIQUE(FILTRE(n; n <> 0)));
ASSEMB.H(u; SIERREUR(EXCLURE(REDUCE(""; u; LAMBDA(a; c; ASSEMB.V(a; TRIER(TRANSPOSE(FILTRE(PRENDRE(p; ; -1); n = c)); ; ; 1)))); 1); ""))
)
Franchement c' est génial JFL
Bonjour à tous de nouveau !
Ce tri décroissant concernerait la colonne 1 ou les valeurs associées ?
Bonjour à tous,
Oh, il y a du beau monde !
Une version 365 également. A l'aide de 2 formules. Trier en ordre décroissant et sans doublons.
La première :
=EXCLURE(TRIER(UNIQUE(DANSCOL(INDEX(B1:AA8;LIGNE(1:8);{1.3.5.7.9.11.13.15.17.19.21.23.25}))));-1)La deuxième basée sur la première, à étendre vers le bas :
=LET(
a;DANSCOL(INDEX($B$1:$AA$8;LIGNE($1:$8);{1.3.5.7.9.11.13.15.17.19.21.23.25}));
b;DANSCOL(INDEX($B$1:$AA$8;LIGNE($1:$8);{2.4.6.8.10.12.14.16.18.20.22.24.26}));
TRANSPOSE(TRIER(UNIQUE(FILTRE(b;a=B12));;-1)))Résultat :
Ne pas oublier de mettre à jour le profil car tu as l'air d'avoir office 365
bonsoir JFL il concerne les valeurs associées
Bonsoir JB, c' est bien ce que je veux mais avec les doublons des colonnes associées
Il suffit de supprimer la fonction UNIQUE :
=LET(
a;DANSCOL(INDEX($B$1:$AA$8;LIGNE($1:$8);{1.3.5.7.9.11.13.15.17.19.21.23.25}));
b;DANSCOL(INDEX($B$1:$AA$8;LIGNE($1:$8);{2.4.6.8.10.12.14.16.18.20.22.24.26}));
TRANSPOSE(TRIER(FILTRE(b;a=B12);;-1)))Merci infiniment JB, j' ai ce que je voulais
Je vous souhaite un très bon week-end.
Bonjour à tous de nouveau !
Pour un tri décroissant (formule unique et avec un dynamisme assuré indépendamment du nombre de lignes et de colonnes....
=LET(
p;ORGA.LIGNES(DANSCOL(B1:AA8);2);
n;PRENDRE(p;;1);
u;TRIER(UNIQUE(FILTRE(n;n<>0)));
ASSEMB.H(u;SIERREUR(EXCLURE(REDUCE("";u;LAMBDA(a;c;ASSEMB.V(a;TRIER(TRANSPOSE(FILTRE(PRENDRE(p;;-1);n=c));;-1;1))));1);""))
)
Merci à toi JFL c' est parfait.
Encore merci à tous de m' avoir donné de votre temps, je suis reconnaissant
Bonne soirée à tout le monde
Bonsoir à tous !
Bien....
Je vous remercie de ce retour.
(Ne pas oublier de modifier votre profil....)