Chercher nom image dans une cellule

Bonjour

J'aimerai récupérer le nom de l'image contenu dans une cellule sans cliquer sur l'image. Par exemple la cellule D8 contient une image et je ne sais pas récupérer son nom sans cliquer sur l'image. Est-ce possible ? Ça fait un moment que je cherche et je ne trouve pas la solution. Merci pour votre aide.

Bonjour JLA32

Normalement une image est un objet Shape, il suffit de les parcourir pour définir dans quelle cellule il se trouve
(faites une recherche la dessus)

Et sinon, pourquoi ce genre de question

Bonjour,

Et pourquoi ne pas adjoindre un commentaire à la cellule contenant l'image, commentaire contenant le nom de l'image
Alors en passant la souris sur cette cellule le commentaire apparaitra et donc le nom de l'image

Bonne journée

Bonjour JLA32, à tous les autres,

Voici une fonction personnalisée qui retourne les noms des images d'une plage de cellules.

• La plage peut-être réduite à une seule cellule ou bien être maximisée à la feuille entière.
• La fonction retourne une chaine de caractères avec les noms des images séparés par une virgule. S'il n'y a pas d'image dans la plage alors la fonction retourne la chaine vide "".

...

La fonction s'appelle : RecupPlageNomImage

Elle possède deux paramètres :

1. Le premier paramètre s'appelle Plage et il est obligatoirement présent. C'est la plage pour laquelle chercher les images.
2. Le second paramètre s'appelle Partiel et il est facultatif. Il est soit absent soit il peut valoir n'importe quoi. S'il est absent, les images prise en compte doivent être entièrement contenues dans la plage. S'il est présent (et vaut n'importe quoi), alors on prend non seulement les images entièrement contenues dans la plage mais aussi les images chevauchant partiellement la plage.

...

Dans la classeur deux utilisations :

1. en formule de feuille de calcul.
2. dans une macro VBA nommée Utilisation(). Sélectionnez une plage de la feuille de calcul puis cliquez sur le bouton bleu pour lancer la macro.

...

Le code de la macro :

Function RecupPlageNomImage$(Plage As Range, Optional Partiel)
Application.Volatile
Dim shp, shpRange As Range, res$, InterRange As Range
   With Plage.Parent
      For Each shp In .Shapes
         Set shpRange = .Range(shp.TopLeftCell, shp.BottomRightCell)
         Set InterRange = Intersect(shpRange, Plage)
         If IsMissing(Partiel) Then
            If Not InterRange Is Nothing Then If InterRange.Address = shpRange.Address Then res = res & ";" & shp.Name
         Else
            If Not InterRange Is Nothing Then res = res & ";" & shp.Name
         End If
      Next shp
   End With
   RecupPlageNomImage$ = Mid(res, 2)
End Function

...

nota : la fonction (même si elle déclarée volatile) ne se réactualise pas si on ajoute, retire, redimensionne ou déplace une image. Excel ne fait rien de ces évènements. Donc il faut forcer le calcul de la feuille après de telles actions (touche de fonction F9). Plus généralement c'est la même chose quand on agit au niveau des couleurs de cellules, de leur format, de leur largeur ou hauteur, ça ne déclenche pas le recalcul.

Merci pour vos conseils mais ça ne répond pas vraiment à ce que je veux. Sans cliquer sur l'image et sans me positionner sur la cellule je cherche à récupérer le nom de l'image qu'elle contient. Dans ma procédure je veux indiquer la ligne et la colonne de ma cellule et qu'en retour je récupère le nom de l'image qu'elle contient. Je ne suis pas sûr que ce soit possible mais ça m'aiderait beaucoup. Merci

Re,

Pour info, c'est ce que fait le code de mafraise que je salue

Mais si vous ne savez pas ce qu'est une fonction... alors là...

Re JLA32 et bonjour à JExceL2fr que je salue aussi ,

Le code suivant récupère le nom des images entièrement contenu dans la cellule en ligne i et colonne j de la feuille active (i est un nombre, j peut-être un nombre ou des lettres) :

Dim Nom as string
Nom = RecupPlageNomImage(cells (i,j) )

Il faut bien sûr mettre dans un module de code le code de la fonction RecupPlageNomImage pour pouvoir l'utiliser.

Ou bien, nous joindre le classeur pour qu'on puisse voir ce qu'on peut vous proposer de pertinent.

Merci mafraise

C'est exactement ce que je cherchais