Formule reduction famille

Bonjour,

j'ai un tableau avec des données concernant des membres

j'aimerai trouver un automatisme pour afficher le type de réduction (N,R1,R2,R3), cette réduction s'applique pour les membres vivant sous un même toit et par âge du plus vieux au plus jeune

est-ce possible de créer cela via l'adresse ??

voici un exemple du fichier

d'avance merci de votre retour

Bonjour,

Ci-joint ma solution. Cela implique que le tableau soit trier dans l'ordre suivant :

Ajout de 2 colonnes intermédiaires.

Puis la formule suivante devrait faire le job :

=SI([@Nb]=1;$H$23;RECHERCHEX([@Idx];$G$24:$G$27;$H$24:$H$27;;0))

Je te laisse regarder !

EDIT : On peut également adapter la formule pour le montant de l'abonnement :

=SI([@Nb]=1;$L$24;RECHERCHEX([@Idx];$G$24:$G$27;$L$24+$I$24:$I$27*$L$24;;0))

Bonjour cindyh,

Si le type de réduction doit être figé et ne pas évoluer (voir exemple ci-dessous) au fil des inscriptions des membres d'une même famille, je ne vois qu'une solution en VBA. Je me pose cette question car si le type de réduction est évolutif au fil des inscriptions, j'imagine que cela peut compliquer les encaissements ...

Exemple : famille composée des membres du plus âgé au plus jeune : M1, M2, M3, M4, M5

1. Inscription = de M1 et M4
   1. M1 => 100%, M4 => 95%
2. Puis plus tard inscription supplémentaire de M2
   1. M1 => 100%, M2 => 95%, M4 => 90% : ce que fera une solution par formule, les types de réduction vont évoluer
   2. M1 => 100%, M2 => 90%, M4 => 95% : possible avec une solution VBA, les types de réduction sont figés mais il reste le problème de la désinscription d'un membre ...

Cdlt,

Cylfo

Bonjour à tous !

Une proposition "formule", type unique et dynamique, pour M365 à jour (Insider ?) en K2 :

=LET(
    nais; C2:C13;
    adre; E2:E13;
    redu; $H$24:$H$27;
    MAP(
        nais;
        adre;
        LAMBDA(n; a;
            LET(
                f; TRIER(FILTRE(nais; adre = a); 1; 1);
                l; LIGNES(f);
                SI(
                    l = 1;
                    "N";
                    RECHERCHEX(n; f; MAKEARRAY(l; 1; LAMBDA(l; c; INDEX(redu; MIN(l; LIGNES(redu)); c))); ; 0)
                )
            )
        )
    )
)

Remarque : Ne gère pas les naissances multiples.....

Bonjour,

merci pour votre retour, mon M365 est à jour et je ne vois pas comment intégrer en k2 votre proposition de formule unique et dynamique

le vba n'est pas mon fort ;-)

Bonjour à tous de nouveau !

.... je ne vois pas comment intégrer en k2 votre proposition de formule unique et dynamique

par le biais d'un simple copier/coller de la formule en K2 (ou H2) !