Fonction EQUIV avec plage sur plusieurs colonnes
Bonjour,
J'ai l'habitude d'utiliser la fonction EQUIV en utilisant une plage sur une colonne et ça fonctionne correctement.
J'ai besoin d'utiliser la même fonction mais avec une plage sur plusieurs colonnes et là ça ne marche plus.
Quand je sélectionne le numéro de véhicule je veux savoir à qui il appartient. Sachant que chaque personne peut avoir plusieurs véhicules.
Le code : =INDEX(B3:E6;EQUIV(C9;C3:E6;0);1) ne fonctionne pas, il ne prend pas la plage C3:E6.
Une idée ?
Merci d'avance pour vos retours
bonjour
voila
INDEX(B3:B6;SOMMEPROD(MAX((C3:E6=C9)*LIGNE(B3:B6)))-2)cordialement
C'est tout bon.
Un grand merci.
Bon après-midi
Bonjour à tous
Pour s'amuser, voici une formule un peu plus longue mais qui traite aussi quelques cas particuliers :
- Véhicule inconnu
- Propriétaires multiples
- Plusieurs propriétaires mais tous les mêmes
=SI(C9="";"";SI(NB.SI(C3:E6;C9)=0;"Véhicule inconnu";SI(PETITE.VALEUR(SI(C3:E6=C9;LIGNE(B3:B6));1)<>GRANDE.VALEUR(SI(C3:E6=C9;LIGNE(B3:B6));1);"Propriétaires multiples";INDEX(B:B;PETITE.VALEUR(SI(C3:E6=C9;LIGNE(B3:B6));1)))))
Bonjour à tous !
Une autre approche multi-cas (@mafraise :
=JOINDRE.TEXTE(" / ";;FILTRE(B3:B6;BYROW(N(C3:E6=C9);SOMME);"Inconnu"))
Bonjour à tous,
@JFL
Insider aurait-il encore frappé ?
Votre formule est en erreur avec un Excel 365 de base, mais la suivante non :
=JOINDRE.TEXTE(" / ";;FILTRE(B3:B6;BYROW(N(C3:E6=C9);LAMBDA(p;SOMME(p)));"Inconnu"))Bonjour à tous de nouveau !
Insider aurait-il encore frappé ?
Votre formule est en erreur avec un Excel 365 de base
C'est fort possible...
Il y a longtemps que j'ai abandonné l'idée de comprendre la disponibilité des fonctions nouvelles.
Pour ma lanterne, pouvez-vous me dire la périodicité de vos mises à jour ? (mensuelles ? semestrielles ?)
Bonjour @FLV,
Chez moi itou, pas le dernier 365
Re,
Cette fonction est compatible avec Excel 365 de base. Pas jolie mais elle le fait :
=SIERREUR(JOINDRE.TEXTE("; ";VRAI;UNIQUE( FILTRE(ASSEMB.V(B3:B6;B3:B6;B3:B6);ASSEMB.V(C3:C6;D3:D6;E3:E6)=C9)));"inconnu")ou
=SIERREUR(JOINDRE.TEXTE("; ";VRAI;UNIQUE( FILTRE(ASSEMB.V(B3:B6;B3:B6;B3:B6);DANSCOL(C3:E6)=C9)));"inconnu")Bonsoir à tous !
En version un tantinet moins moderne :
=JOINDRE.TEXTE(" / ";;FILTRE(B3:B6;PRODUITMAT(N(C3:E6=C9);SEQUENCE(3;;1;0));"Inconnu"))Re JFL
Elle me plait bien la petite dernière
Bonjour à tous,
Pour rappel, la formule que je vous ai indiquée est compatible Excel 365 de base :
=JOINDRE.TEXTE(" / ";;FILTRE(B3:B6;BYROW(N(C3:E6=C9);LAMBDA(p;SOMME(p)));"Inconnu"))Et pour ma part je ne m'occupe pas des mises à jour, elles sont en automatique.