Renvoyer l'en tête de la colonne à partir d'une valeur

Bonjour, je ne trouve pas comment renvoyer l'en tête de la colonne à partir d'une donnée de celle ci. J'ai un tableau avec plusieurs valeurs et un tableau de sortie qui renvoie la valeur la plus faible. j'aimerais pouvoir renvoyer aussi le nom de la colonne. Je joins le fichier correspondant merci d'avance.

Bonjour,

Une proposition, si la recherche ne se fait toujours que sur une ligne.

Cordialement

Bonjour à tous !

Et....

Une proposition formule unique et dynamique ?

=LET(
    t; _Tableau_calculs[#Tout];
    BYCOL(C11:D11; LAMBDA(c; FILTRE(PRENDRE(t; 1); PRODUITMAT(SEQUENCE(; LIGNES(t) - 1; 1; 0); --(EXCLURE(t; 1) = c)))))
)

bonsoir

une contribution

cordialement

Bonjour,

Merci pour vos participations, j'ai l'impression que ma demande était peut clair je l'ai précisé dans le fichier ci joint. @JFL votre formule me semble très intéressante malheureusement cela me renvoi !VALEUR, est ce que je doit rajouter une fonction SIERREUR ? Merci d'avance.

Pour les deux autres propositions j'ai l'impression qu'elle ne réponde pas à ma requête ou alors j'aimerais bien que vous m'expliquiez votre procédé. Merci d'avance

Après, l'ajout d'une fonction SIERREUR comme ceci, cela fonctionne,

=LET(
t;SIERREUR(_Tableau_calculs[#Tout];1000000);
BYCOL(C11:D11;LAMBDA(c;FILTRE(PRENDRE(t;1);PRODUITMAT(SEQUENCE(;LIGNES(t)-1;1;0);--(EXCLURE(t;1)=c))))))

merci beaucoup pour votre contribution @JFL

Bonjour à tous !

Si votre besoin réel est de générer automatiquement un tableau des valeurs minima, ainsi que les en-têtes correspondants, je vous propose de tester la formule unique et dynamique suivante :

=LET(
    t; _Tableau_calculs[#Tout];
    vm; TRANSPOSE(BYROW(EXCLURE(t; 1); LAMBDA(r; MIN(r))));
    et; CHOISIRCOLS(_Tableau_calculs[#En-têtes]; BYROW(_Tableau_calculs; LAMBDA(r; EQUIV(MIN(r); r; 0))));
    ASSEMB.V(et; vm)
)

@JFL

En effet, la dernière formule m'intéresse malheureusement cela me renvoi l'erreur !VALEUR

Bonjour à tous !

Etrange......

Il se peut que votre souci vienne de la source de vos données ?

N'ayant pas accès à cette source, j'ai testé sur des valeurs fictives :

@JFL

L'objectif serait de renvoyer l'en tête de la valeur minimum et sa ref, dan votre exemple ce serait azazaz centrale z

Bonjour à tous de nouveau !

Il me semble que vous ajoutez des contraintes à chaque message....

Initialement, il était question de déterminer l'en-tête d'un minimum.

Ensuite il fallait une double détermination automatique (minima et en-tête).

Et maintenant il faudrait retourner aussi la référence.....

Ce "feuilletonnage" est chronophage.....

L'objectif serait de renvoyer l'en tête de la valeur minimum et sa ref, dan votre exemple ce serait azazaz centrale z

Objectif non explicite..... : en-tête et référence ou référence et en-tête ?

Oui en effet, c'est juste qu'au fur et à mesure des solutions apportées, d'autres problèmes sont apparus. Je pense que mon dernier post décris au mieux le besoin. Si vous n'avez pas le temps de m'aider je pourrais le comprendre.

Merci pour le temps déjà accordé

Bonjour à tous de nouveau !

Proposition amendée avec deux présentations :

Bonjour à tous !

Un petit retour.... ?

Bonjour, comment ne pas afficher la colonne Q avec les valeurs, si vous avez le temps j'aimerai aussi comprendre le fonctionnement de cette fonction dynamique que vous utilisez

Bonjour à tous !

Est-ce là le retour attendu ?

Si oui, alors je vous propose de tester la formule suivante :

=LET(
    t; _Tableau_calculs[#Tout];
    et; CHOISIRCOLS(PRENDRE(t; 1); BYROW(EXCLURE(t; 1); LAMBDA(r; EQUIV(MIN(r); r; 0))));
    ASSEMB.H(TRANSPOSE(et); EXCLURE(PRENDRE(t; ; 1); 1))
)

Les titres des champs peuvent, si besoin est, être intégrés directement dans la formule.

Commentaires sur la formule :

• La fonction LET permet de "variabiliser" les calculs intermédiaires.
• la variable "t" charge en mémoire le tableau structuré _Tableau_calculs dans son entièreté (données et en-têtes).
• la variable "et" stocke le vecteur des en-têtes correspondants au minimum de chaque ligne.
• La dernière ligne de la formule assemble le vecteur "et" avec les "N° entrée" pour produire le tableau attendu.

Bonjour, c'est parfait merci beaucoup

Bonjour à tous de nouveau !

Bien....

Je vous remercie de ce retour.

Si on a envie de jouer sur les lignes du tableau on choisira la fonction CHOISIRLIGNES à la place de CHOISIRCOLS ?

(cette question est posée par simple curiosité, mon problème est résolu)

Bonjour à tous de nouveau !

Absolument.

Bien veiller à la cohérence entre la fonction et la matrice passée en premier argument.