Liste de données en fonction d'une cellule

Bonjour,

Je voudrais savoir si il est possible en fonction de ce que la cellule contient d'afficher la liste de données qui lui correspond.

Voici les informations que je voudrais mettre sous formes de liste dans le fichier

J'ai oublié de préciser l'objectif est de simplifier la lecture du tableau pour seulement afficher les éléments voulu par exemple si il s'agit d'un treillis afficher seulement les données qui lui corresponde.

Bonjour,

Avec la fonction FILTRE :

Avec la valeur en H2 :

=FILTRE(A3:F57;D3:D57=H1)

Par contre, les cellules fusionnées de la colonne A n'appartiendront pas forcément.

Daniel

[EDIT] H1, pas H2.

Merci bien.

J'aurais une autre petite question il est possible de relié directement les cellules de la colonne F aux cellules qui correspondent en colonne D par exemple Arc en béton armé avec IM1 et faire de même pour tous

Je ne comprends pas ce que tu veux dire par relier. Est-ce que tu peux donner un exemple ?

Oui bien sûr,

Voici l'exemple :

- Choix dans la liste déroulante du fonctionnement mécanique principal (Arc, voûte ...)

-Avec ce choix la cellule suivante me donne les structure possible dans une autre liste déroulante dans laquelle je choisis celle qui correspond (Arc en béton armé...)

-Avec ce choix de structure on me donne directement le code identifiant mécanique.

C'est faisable sauf que, en colonne A, on n'a pas l'info sur toutes les lignes. est-ce qu'il est possible de l'avoir ?

Regarde le classeur joint :

Pour la colonne A, c'est A=Arc et ainsi de suite.

J'ai regardé le classeur et c'est la bonne voie mais quelles sont les formules et la méthode utilisée ?

En O2 : liste triée des valeurs uniques de la colonne A :

=TRIER(UNIQUE(A3:A57))

La liste de validation en H2 :

=O2#

En P1, transposition de la liste précédente :

=TRANSPOSE(TRIER(UNIQUE(A3:A57)))

En P2, à tirer vers la droite, liste des valeurs de la colonne D par code de la colonne A :

=TRIER(FILTRE($D$3:$D$57;($A$3:$A$57=P$1)))

En H4, validation de données avec la formule :

=DECALER($O$2;;EQUIV($H$2;$P$1#;0);NBVAL(DECALER($A:$A;;EQUIV($H$2;$P$1#;0)+13)))

";EQUIV($H$2;$P$1#;0)" représente le décalage horizontal de la valeur de H2 par rapport à O2.

"NBVAL(DECALER($A:$A;;EQUIV($H$2;$P$1#;0)+13" représente le nombre de valeurs correspondant à H2

=DECALER($O$2;;EQUIV($H$2;$P$1#;0);NBVAL(DECALER($A:$A;;EQUIV($H$2;$P$1#;0)+13)))

C'est à dire, la plage de valeurs correspondant à la valeur en H2.

Daniel

Merci je vais faire mon tableau avec cette méthode.