Recherche V et Si
Bonsoir,
j'ai encore besoin de votre aide pour calculer des records.
J'ai un classeur excel avec une feuille par année et dans chauqe feuille, j'ai toutes les disciplines, le nom des athlètes et leurs catagories.
Je vous ai mis un exemple de feuille .
Je souhaiterais fair ressortir tous les records par année, par discipline et par catégorie.
Alors j'ai pensé à la recherche V avec une liste déroulante pour la catégorie
ensuite avec une fonction SI avec comme résultat une minimum pour les courses et une maximum pour les lancers.
Sauf que les 2 ne fonctionnent pas ensemble grrr
La si Nic quel mais pas avec la liste déroulante
Par exemple je voudrai la minimimu de la discipline 1500 m sur la catégorie SEM?
Si vous pouvez m'aider ce serait super
Merci à vous et très bonne soirée
Bonjour,
En colonne C :
=MIN(DECALER(INDIRECT("'perf "&DROITE(Table_25[[#En-têtes];[Record 2019]];4)&"'!A:A");;EQUIV([@Discipline];'perf 2019'!$1:$1;0)-1))Avec le format personnalisé :
00'00''00;;
Pour éliminer les valeurs nulles.
Note le "perf 2019" de la formule peut être utilisé pour les autres feuilles.
Daniel
bonjour
merci pour vos réponses.
Eric, eEn croisés dynamiques, c'est vrai que c'est une possibilité mais ça demande de changer toutes les feuilles (car une par année) et je ne veux que les records du club par catégorie et par année... je vais voir aussi
Daniel, la formule nicquel maintenat est-il possible d'ajouter une recherche V pour voir apparaitre après le nom et la catégorie du record en ajoutant une colonne du coup je ne sais pas trop?
Merci à vous 2 pour votre aide
Bonne journée
Bonjour,
Essaie, en B4 :
=SIERREUR(INDEX(INDIRECT("'perf "&DROITE(Table_25[[#En-têtes];[Record 2019]];4)&"'!A:A");EQUIV([@[Record 2019]];DECALER(INDIRECT("'perf "&DROITE(Table_25[[#En-têtes];[Record 2019]];4)&"'!A:A");;EQUIV($A4;'perf 2019'!$1:$1;0)-1);0));"")Daniel
Merci Daniel,
Ca marche nicquel. Pourriez vous m'expliquer un peu la formule pour que je la reproduise? et je pourrais faire la même pour la catégorie du coup?
Merci encore
Re,
j'essaye de reproduire la formule mais je ne vois pas à quoi corresponds la table 25 ((Table_25[[#En-têtes]
Merci
Je viens de m'apercevoir que les formules n'étaient pas généralisables aux autres années. Les formules rectifiées sont donc, respectivement pour le temps et pour le nom :
=MIN(DECALER(INDIRECT("'perf "&DROITE(C$3;4)&"'!A:A");;EQUIV([@Discipline];'perf 2019'!$1:$1;0)-1))
et
=SIERREUR(INDEX(INDIRECT("'perf "&DROITE(C$3;4)&"'!A:A");EQUIV([@[Record 2019]];DECALER(INDIRECT("'perf "&DROITE(C$3;4)&"'!A:A");;EQUIV($A10;'perf 2019'!$1:$1;0)-1);0));"")Pour la catégorie, la formule est :
=SIERREUR(INDEX(INDIRECT("'perf "&DROITE(C$3;4)&"'!B:B");EQUIV([@[Record 2019]];DECALER(INDIRECT("'perf "&DROITE(C$3;4)&"'!A:A");;EQUIV($A4;'perf 2019'!$1:$1;0)-1);0));"")pour la ligne 3.
Les formules sont à recopier sans modification pour les autres années.
INDIRECT("'perf "&DROITE(C$3;4)&"'!A:A")Cette formule désigne la colonne A de la feuille dont l'année figure en C3 (pour la catégorie, j'ai mis la colonne B) :
INDIRECT("'perf "&DROITE(C$3;4)&"'!B:B")Pour déterminer la colonne des temps,
EQUIV([@Discipline];'perf 2019'!$1:$1;0)qui renvoie le numéro de colonne de la discipline sur les feuilles années.
DECALER(INDIRECT("'perf "&DROITE(C$3;4)&"'!A:A");;EQUIV([@Discipline];'perf 2019'!$1:$1;0)-1)Est le décalage par rapport à la colonne A correspondant à la discipline, soit la plage des temps :
Enfin, la fonction MIN renvoie la plus petite valeur.
Pour les noms :
la dernière formule sert également à renvoyer la plage des temps de la discipline considérée. On la reprend pour trouver la ligne où se trouve le record de la discipline :
EQUIV([@[Record 2019]];DECALER(INDIRECT("'perf "&DROITE(C$3;4)&"'!A:A");;EQUIV($A18;'perf 2019'!$1:$1;0)-1);0)La fonction INDEX se sert de cette dernière formule pour renvoyer le nom attaché au record :
(INDEX(INDIRECT("'perf "&DROITE(C$3;4)&"'!A:A");EQUIV([@[Record 2019]];DECALER(INDIRECT("'perf "&DROITE(C$3;4)&"'!A:A");;EQUIV($A18;'perf 2019'!$1:$1;0)-1);0))Enfin SIERREUR n'affiche rien en cas d'erreur.
Ouf. N'hésite pas à poser des questions.
Daniel
OUAH quel pro!! Je connais bien la bureautique mais la c'est plus que du expert! bravo et merci
Si je peux abuser de ta gentillesse, j'ai essayé de reproduire tes formules à l'identique mais ca n'a pas voulu copier sur mes autres années.
J'ai recréé un fichier récap avec toutes mes feuilles années.
J'ai ajouté des colonnes athlètes et catégorie par chaque année.
J'ai pensé a faire une liste déroulante avec mes catégorie dans la feuille à ne pas toucher mais veut pas mais bon.
je te mets mon fichier en pièce jointe avec toutes les feuilles excel et mon potentiel records club.
Merci encore pour ton aide, j'aimerais bien me former pour en faire autant! si tu as des astuces je suis preneuse😁
Vérifie.
Bonsoir,
Extra, tu es génial!!
Merci beaucoup
Je teste et encore une petite question:
Quand je saisi un nouveau record, ça ne se met pas jour? y a t'il une manip supplémentaire a faire?
Merci encore je sais j'abuse
non t'inquiète je crois que j'ai trouvé pourquoi : pour les lancers c'est une maximum donc faut juste que je change le min en MAX🤣
En plus faut connaitre l'athlétisme👍👍👍
C'est parfait encore merci
https://insider.microsoft365.com/rss/blog
Normalement, si. Dis-moi ce que tu saisis.
Daniel
Pas de souci, j'ai juste changer la formule pour les lancers et sauts en "max" au lieu de "min" et ca se mets a jours parfaitement
merci