Insert de photo selon valeur d'une cellule

Bonjour,

Je cherche à ce que la macro cherche la référence dans un dossier photo (la photo aura le nom de la référence) , et affiche la photo (avec une taille définie dans un une feuille paramètres). La référence est écrite en C3.

Je n'ai pas trouvé de solutions malgré que je cherche partout sur google...

J'aimerais que cela rentre dans le cadre photo !

merci à vous par avance ! :)

Bonjour,

Exemple d'un code pour réaliser un trombinoscope :

Soit le tableau structuré "t_Images".

Sub ImporterLesImages()

Dim ListeDesImages As Range, CelluleImage As Range, CelluleDestination As Range
Dim Img As Object 'WIA.ImageFile
Dim ImageLargeur As Single, ImageRatio As Single
Dim MonImage As Shape
Dim RepertoireImage As String
Dim ShImage As Worksheet

    Set ListeDesImages = Range("t_Images[Images]")
    Set ShImage = Sheets(Range("OngletDestination").Value)

    With ShImage

         ' Suppression des images existantes
         '----------------------------------
         If .Shapes.Count > 0 Then
            For Each MonImage In .Shapes
                If MonImage.Name = "ImageFeuille" Then MonImage.Delete
            Next MonImage
         End If

         Set Img = CreateObject("WIA.ImageFile")

         For Each CelluleImage In ListeDesImages

             RepertoireImage = CelluleImage.Offset(0, 1)
             ' Recherche des proportions de l'image
             '-------------------------------------
             With Img
                  .LoadFile RepertoireImage & "\" & CelluleImage
                  ImageRatio = .Width / .Height
             End With

             If CelluleImage.Offset(0, 2) <> "" Then    ' Adresse cellule exemple : C7
                Set CelluleDestination = ShImage.Range(CelluleImage.Offset(0, 2))
                ImageLargeur = CelluleDestination.Width  ' Pour fixer la largeur de l'image à la largeur de la colonne prévue

                ' Insertion de l'image
                '---------------------
                Set MonImage = .Shapes.AddShape(msoShapeRectangle, CelluleDestination.Left, CelluleDestination.Top, ImageLargeur, ImageLargeur / ImageRatio)
                With MonImage
                     .Name = "ImageFeuille" ' permet d'identifier une shape contenant une image
                     With .Fill
                          .Visible = msoTrue
                          .UserPicture RepertoireImage & "\" & CelluleImage
                     End With
                     With .Line
                          .Visible = msoTrue
                          .Weight = 1
                     End With
                End With
                Set MonImage = Nothing
                Set CelluleDestination = Nothing
             End If

         Next CelluleImage

         .Activate

         MsgBox "Fin du chargement !", vbInformation, "Chargement des images"

    End With

    Set Img = Nothing
    Set ListeDesImages = Nothing
    Set ShImage = Nothing

End Sub

Bonjour,

merci pour le message,

est-il possible d'avoir un fichier pour être sure qu'on parle de la meme chose?

merci

Bonjour,

Help me svp

Bonjour,

Voila un fichier avec une macro qui recupere la valeur de la cellule c3 et qui va chercher dans un dossier l'image du meme nom

la taille est definie par les cellules y2 et y3

Cdlt