Selection de lignes selon dates
Hello,
Ci-joint un exemple de liste, créé à partir d'un QUERY réalisé grâce à ce forum :
(le QUERY a été fait grâce à ça : https://forum.excel-pratique.com/sheets/comptage-complexe-d-elements-174653)
Il y a donc un gros tableau évolutif, sur lequel on rajoute des lignes (non présent sur cet exemple).
Le tableau de gauche "LISTE RANDO " filtre et agrège ces données, pour sortir cette liste.
Cette liste évolue donc automatiquement en fonction de nos réservations reçues.
À droite, un tableau manuel "BILAN MENSUEL" pour faire le bilan de cette liste mois par mois.
Rien de bien compliqué dans les formules des 3 premières colonnes L, M, N. Sauf que les plages ne sont pas mises à jour avec l'apparition de nouvelles lignes dans le tableau de gauche...... il faut donc que le vérifie les lignes correspondantes au 1er et dernier jour de chaque mois, pour mettre à jour ces formules…. relou.
Je soupçonne de belles formules VLOOKUP, mais n'arrive pas à les syntaxer...
En bon français :
Pour L3 : Compter nombre de lignes dans C5:C999 SI B5:CB999 est entre le 1er et le 31 janvier
Pour M3 : Somme de C5:C999 SI B5:CB999 est entre le 1er et le 31 janvier
Pour N3 : Somme de I5:I999 SI B5:CB999 est entre le 1er et le 31 janvier
Très grand merci pour votre aide.
Bonsoir Renaud,
Tu peux utiliser ça:
=query(B$5:I;"select Count(B), SUM(C), SUM(I) WHERE B>=DATE '2023-01-01' AND B<=DATE '2023-01-31' LABEL SUM(C) '', Count(B)'', SUM(I) ''")
Je mets à jour ton fichier...
Cordialement,
Fil.
Bonjour Renaud,
Finalement, j'ai reproduit ton tableau en une formule unique par ligne:
=IFERROR(query(B$5:I;"select COUNT(B), SUM(C), SUM(I), SUM(I)/Count(B), SUM(I)/SUM(C), SUM(C)/COUNT(B) WHERE B>=DATE '2023-01-01' AND B<=DATE '2023-01-31' LABEL SUM(C) '', COUNT(B)'', SUM(I) '', SUM(I)/Count(B)'', SUM(I)/SUM(C)'', SUM(C)/COUNT(B)''");"")
J'ai également ajouté une MFC pour les mois impairs, afin de faire ressortir visuellement chaque mois:
=mod(TEXT($B5;"m");2)=1
Bonnes randos,
Amicalement,
Fil.
Bonjour Renaud,
Tu peux utiliser cette méthode également, qui à l'avantage de gérer automatiquement les mois de février pour les années bissextiles...
Avec MONTH(B): 0 pour janvier, 1 pour février...11 pour décembre.
=SIERREUR(query(B$5:I;"select COUNT(B), SUM(C), SUM(I), SUM(I)/Count(B), SUM(I)/SUM(C), SUM(C)/COUNT(B) WHERE MONTH(B)=0 AND YEAR(B)=2023 LABEL SUM(C) '', COUNT(B)'', SUM(I) '', SUM(I)/Count(B)'', SUM(I)/SUM(C)'', SUM(C)/COUNT(B)''");"")
Pour le total:
=SIERREUR(query(B$5:I;"select COUNT(B), SUM(C), SUM(I), SUM(I)/Count(B), SUM(I)/SUM(C), SUM(C)/COUNT(B) WHERE YEAR(B)=2023 LABEL SUM(C) '', COUNT(B)'', SUM(I) '', SUM(I)/Count(B)'', SUM(I)/SUM(C)'', SUM(C)/COUNT(B)''");"")
Cordialement,
Fil.
Whaou, fantastique, ça marche nickel sur le fichier de travail.
Heureusement, car je ne comprends pas le quart de la moitié de la formule !
Grand merci !!!