Extraire des données d'une cellule Excel
Bonjour,
Je cherche à séparer des infos sur une chaine de caractère.
Dans une cellule, j'ai l'info suivante : 1 RUE DU SENATEUR BOULARAN 81250 ALBAN
je recherche à obtenir :
- une cellule avec le numéro, ici : 1
- une cellule avec le nom de rue, ici : Rue du sénateur boularan
- une cellule avec le code postal : 81250
- une cellule avec le nom de la ville : Alban
Le tout en respectant les casses finales.
QQ1 pourrait m'aider ?
Merci !
Bonjour,
Une solution avec Excel 365 uniquement :
=INDEX(FRACTIONNER.TEXTE(A1;" ");1)
=TEXTE.AVANT(TEXTE.APRES(A1;INDEX(FRACTIONNER.TEXTE(A1;" ");1));FILTRE(FRACTIONNER.TEXTE(A1;" ");(ESTNUM(FRACTIONNER.TEXTE(A1;" ")*1))*(NBCAR(FRACTIONNER.TEXTE(A1;" "))=5)))
=FILTRE(FRACTIONNER.TEXTE(A1;" ");(ESTNUM(FRACTIONNER.TEXTE(A1;" ")*1))*(NBCAR(FRACTIONNER.TEXTE(A1;" "))=5))
=TEXTE.APRES(A1;FILTRE(FRACTIONNER.TEXTE(A1;" ");(ESTNUM(FRACTIONNER.TEXTE(A1;" ")*1))*(NBCAR(FRACTIONNER.TEXTE(A1;" "))=5)))Tu peux malgré tout avoir des problèmes avec les n°s bis, ter etc.
Daniel
Version optimisée :
=INDEX(FRACTIONNER.TEXTE(A1;" ");1)
=LET(tf;FRACTIONNER.TEXTE(A1;" ");FILTRE(tf;(ESTNUM(tf*1))*(NBCAR(tf)=5)))
=LET(tf;FRACTIONNER.TEXTE(A1;" ");TEXTE.APRES(A1;FILTRE(tf;(ESTNUM(tf*1))*(NBCAR(tf)=5))))
=LET(tf;FRACTIONNER.TEXTE(A1;" ");TEXTE.AVANT(TEXTE.APRES(A1;INDEX(tf;1));FILTRE(tf;(ESTNUM(tf*1))*(NBCAR(tf)=5))))Daniel
Bonjour le forum,
La décortiqueuse saison 2
Voir ligne 2
Cordialement.
Bonjour à tous !
Pour Excel 365 : Formule unique.
Gère l'absence de numéro mais pas les "Bis, ter...." :
=LET(
t_;A1;
m_;FRACTIONNER.TEXTE(t_;" ");
m_Num;SIERREUR(INDEX(m_;1)*1;"");
m_CP;FILTRE(m_;(ESTNUM(m_*1))*(NBCAR(m_)=5));
m_V;TEXTE.APRES(t_;m_CP&" ");
m_R;SI(m_Num<>""; TEXTE.APRES(TEXTE.AVANT(t_;" "&m_CP);m_Num&" ");TEXTE.AVANT(t_;" "&m_CP));
ASSEMB.H(m_Num;m_R;m_CP;m_V)
)Wow, super, merci à tous pour vos réponses !! Je vais tester tout cela !