Valeur de la cellule immédiatement à gauche

Bonjour
Dans une sélection je recherche la plus petite valeur. Jusque là pas de problème. Mais j'aimerais que s'affiche la valeur immédiatement à gauche de celle que la formule à trouvé. Cela ne devrait pas être trop compliqué mais je coince.

7test-fcyspm.xlsx (9.04 Ko)

Bonjour à tester

=SI(PETITE.VALEUR(G1:L1;1);G1)

Bonjour,
Merci pour votre proposition. Le problème est que la plus petite valeur peut avoir une autre position et donc cela ne correspondrait plus. Dans mon exemple si la plus petite valeur est situé en J1 il faudrait que A1 recoive la valeur de I1.

Bonjour,
Une autre proposition ?
Cdlt.

=LET(
val;$A1;
plg;$G1:$L1;
n;MATCH(MIN(plg);plg;0);
IF(n=1;$G1;INDEX(plg;;n-1))
)

Re
Merci Jean-Eric mais ça ne fonctionne pas. J'ai une erreur #NOM?

Re,
Oups, mon Excel est en langue anglaise !...

=LET(
val;$A1;
plg;$G1:$L1;
n;EQUIV(MIN(plg);plg;0);
IF(n=1;$G1;INDEX(plg;;n-1))
)

Bonjour fcyspm30, le fil,

Une autre proposition :

7test-fcyspm.xlsx (9.74 Ko)

Bonjour à tous,

en formule classique : =INDEX(G1:L1;EQUIV(PETITE.VALEUR(G1:L1;1);G1:L1;0)-1)
#VALEUR si la plus petite est la 1ère vu que tu n'as pas dit ce qu'il fallait faire dans ce cas
eric

Re,

Pour eriiic si c'est la première on peut mettre 0. La formule fonctionne parfaitement. La formule d'Antoine fonctionne bien aussi. Merci pour vos réponses.

dans ce cas : =SIERREUR(INDEX(G1:L1;EQUIV(PETITE.VALEUR(G1:L1;1);G1:L1;0)-1);0)

Bonsoir à tous !

@Jean-Eric,
Une petite correction de la formule !?

=LET(
val;$A1;
plg;$G1:$L1;
n;EQUIV(MIN(plg);plg;0);
IF(n=1;$G1;INDEX(plg;;n-1))
)

devient :

=LET(
plg;$G1:$L1;
n;EQUIV(MIN(plg);plg;0);
SI(n=1;$G1;INDEX(plg;;n-1))
)

Me trompe-je ?

Rechercher des sujets similaires à "valeur immediatement gauche"