Calculer le nombre apparition de valeur d'une cellule dans une plage

Bonjour,

je souhaite calculer le nombre de fois qu'apparaît le prénom X dans la colonne A

et faire affiche le résultat dans le cellule B2 par exemple

j'ai commence à faire une boucle for et j'aimerais conserver celle-ci

je ne comprends pas comme lui faire calculer le nombre de répétition

Merci à vous

bonjour

une idee

=NB.SI(A:A;A1)

merciiiiii

Bonsoir Jeremylavergne, iliyes, le forum,

Par macro....

Sub calcul()
    Dim i As Integer, dl As Integer
    Dim compteur As Integer
    Dim name As String

       name = InputBox("veuillez saisir le prénom")
   compteur = 0

   If name = "" Or name = vbNullString Then Exit Sub

   With Sheets("Feuil1")
    dl = .Range("A" & Rows.Count).End(xlUp).Row
     For i = 1 To dl
      If UCase(Cells(i, 1)) = UCase(name) Then compteur = compteur + 1
     Next i
   End With
   MsgBox name & " apparait " & compteur & " fois"
End Sub

Sub calcul_2()
 Dim i As Integer, dl As Integer, plage As Range
 Dim compteur As Integer
 Dim name As String

       name = InputBox("veuillez saisir le prénom")
    If name = "" Or name = vbNullString Then Exit Sub

   With Sheets("Feuil1")
    dl = .Range("A" & Rows.Count).End(xlUp).Row
    Set plage = .Range("A1:A" & dl)

     compteur = Application.WorksheetFunction.CountIf(plage, name)
   End With
   MsgBox name & " apparait " & compteur & " fois"
End Sub

Cordialement,

Merci de ta réponse, je vais essayer de comprendre ton code

Sub galopin()
Dim Dico, ArrN, ArrP, S$, o
    Set Dico = CreateObject("Scripting.Dictionary")
    For Each o In Range("A1").CurrentRegion
        S = o.Value
        If Not Dico.Exists(S) Then
            Dico.Add S, 1
        Else
            Dico.Item(S) = Dico.Item(S) + 1
        End If
    Next
    ArrN = Dico.keys  ' transfert dans tableau ArrN(0 To n-1)
    ArrP = Dico.items
    Range("C1").Resize(Dico.Count) = Application.Transpose(ArrN)
    Range("D1").Resize(Dico.Count) = Application.Transpose(ArrP)
End Sub