Classement des couleurs par rapport à leur positionnement

Bonjour à tous

je cherche le classement des couleurs par rapport à leur positionnement (ligne D a K)

de les classer dans l'ordre au fur et à mesure par ligne de (M a Q)

Sachant que le nombre maxi de cellules rouges par ligne est de 5

un petit exemple fait à la main !!

merci d'avance

bonjour,

une solution via une macro

Sub aargh()
    dl = 24 'dernière ligne à adapter
    For i = 3 To dl
        col = 12
        For j = 4 To 11
            If Cells(i, j).Interior.Color = vbRed Then
                col = col + 1
                Cells(i, col) = j - 3
            End If
        Next j
    Next i
End Sub

Bonjour à tous,

Un autre code :

Sub Test()

Dim I As Integer, J As Integer, ColEncours As Integer
Dim AireSource As Range, AireCible As Range

    With ActiveSheet
        Set AireSource = .Range("D3:D24")
        Set AireCible = .Range("M3:M24")

        For I = 1 To AireSource.Count
            ColEncours = 0
            For J = 1 To 8
                If AireSource(I).Offset(0, J - 1).Interior.Color = RGB(255, 0, 0) Then
                   AireCible(I).Offset(0, ColEncours) = J
                   ColEncours = ColEncours + 1
                End If

            Next J

        Next I
    End With

    Set AireSource = Nothing: Set AireCible = Nothing

End Sub

Bonjour à tous,

Un essai....fonction perso....

Option Compare Text

Function Liste_X(titres As Range, Plage_X As Range) As String
 Dim I As Long, Resultat As String
   For I = 1 To titres.Columns.Count 'Parcourir les colonnes
    If Plage_X(1, I) = "x" Then
        'Ajout du nom de l'en-tête à la suite des autres
        If Resultat = "" Then
            Resultat = titres(1, I)
        Else
            Resultat = Resultat & titres(1, I)
        End If
    End If
   Next I
Liste_X = Resultat
End Function

• La case rouge est obtenue en inscrivant un x dans la case....(mfc)....
• La fonction s'utilise comme une formule excel

En M3:

=STXT(Liste_X($D$2:$K$2;$D3:$K3);M$1;1)

A tirer vers la droite puis en bas....

Cordialement,

Bonjour tout le monde,

@xorsankukai , si on se permet d'utiliser "X" pour trouver les cellules rouge on peut même se passer de VBA pour le coup ^^

A+

Bref, tellement de propositions j'espère que legrandcyril y trouvera son compte :D

Bonjour Gabin37,

@xorsankukai , si on se permet d'utiliser "X" pour trouver les cellules rouge on peut même se passer de VBA pour le coup ^^

Argh!!!!!!!!! J'avais bien tenté par formule, mais je n'y suis pas parvenu, d'où le repli vers vba,

Merci pour la formule, je la garde précieusement,

Cordialement,

Merci beaucoup à vous tous