Les dates par semaine (S1,S2,S3,S4)

Bonjour

J ai une colonne avec des dates par jour du mois décembre 2021 à aujourd'hui au format suivant (01/12/2021.......) j'aimerai dans une autre colonne avoir en semaine S1,S2,S3,S4 comment je pourrais faire avec une fonction.

Merci

Cordialement

Bonjour

=NO.SEMAINE.ISO(Ta cellule)

Et si tu tiens absolument au S devant

= "S" & NO.SEMAINE.ISO(Ta cellule)

Bonjour à tous!

saveme, comme ceci peut-être à toutes les 7 cellules incrémenter la valeur de 1

Bonne journée !

pour la fonction =NO.SEMAINE.ISO .Si on prend par exemple 01/12/2021 la fonction me donne comme résultat 48 et non pas 1 puisque c est la première semaine

Effectivement, je n'avais pas compris la demande. Désolé

Bonjour,

Si les dates sont en colonne A et démarrent dès la cellule A1, tu peux mettre 1 en B1, puis la formule suivante en B2 :

=SI(NO.SEMAINE.ISO(A2)<>NO.SEMAINE.ISO(A1);B1+1;B1)

Et si les dates commencent en ligne 2 ou plus bas, c'est plus simple. Tu peux directement mettre ceci en B2 :

=SI(A2=MIN(A:A);1;SI(NO.SEMAINE.ISO(A2)<>NO.SEMAINE.ISO(A1);B1+1;B1))

Bonjour à tous,

Avec l'hypothèse que le 1er de chaque mois (quel que soit le jour) est à considérer comme S1 :

=NO.SEMAINE.ISO(A2)-(NO.SEMAINE.ISO(DATE(ANNEE(A2);MOIS(A2);1))-1)

EDIT : Pour obtenir au format "S1" :

="S"&NO.SEMAINE.ISO(A2)-(NO.SEMAINE.ISO(DATE(ANNEE(A2);MOIS(A2);1))-1)

Bonjour,
Une proposition Excel 365 et +
Pour le fun !
Cdlt.

Début :      01/12/2021
Fin :          =AUJOURDHUI()
Date :          =SEQUENCE(Fin-Début;;Début)
Jour :          =TEXTE(A5#;"jjj")
Semaine :    =TEXTE(RECHERCHEV(SEQUENCE(Fin-Début);CHOISIR({1.2};SEQUENCE(Fin-Début;;1;7);SEQUENCE(Fin-Début;;1;1));2;1);"""S""0")

bonsoir

jean eric en faites ce que je veux c est chaque mois soit diviser sur 4(s1 pour la premiere semaine de tout les mois et s2 pour la semaine de tout les mois que j ai ....) et non pas un incrément de semaine . J'espère bien que je me suis bien expliqué

Je me permets de retenter même si, à priori, nous comptons pour du beurre.

=SIERREUR("S"&SI(OU(A2=MIN(A:A);MOIS(A2)<>MOIS(A1));1;SI(NO.SEMAINE.ISO(A2)<>NO.SEMAINE.ISO(A1);DROITE(C1;1)+1;DROITE(C1;1)));"S1")

"J'espère bien que je me suis bien expliqué"

Presque ... Tu n'as pas dit ce que cela devait faire pour les semaines à cheval sur 2 mois.

Re,
Bonjour JoyeuxNoel,
@saverne,
Il serait intéressant d'avoir un fichier représentatif de tes données avec les résultats escomptés.
Cdlt.

Note : à tester !?

Semaine :     =TEXTE(ENT((JOUR(A5#)-1)/7)+1;"""S""00")

Bonsoir

Jean Eric, la fonction marche bien sauf que ca donne 5 semaine (S01,S02,S03,S04,S05), comment faire pour n'avoir que 4.

Merci

Bonsoir

Joyeux noel , merci pour le temps que vous m avez accordé, j ai appliqué votre proposition mais ca n a pas marché

Cordialement

Bonjour à tous,

Heu....

="S0"&SI(JOUR(A2)<=7;1;SI(JOUR(A2)<=14;2;SI(JOUR(A2)<=21;3;4)))

Cordialement,

Re,
J'ai demandé un fichier avec les résultats escomptés.
Tu ne réponds pas à la question posée. Certainement parce que tu te rends compte de la difficulté.
A te relire.
Cdlt.

Bonsoir à tous,

@Saveme : Par pure "curiosité" (), votre sentiment sur ma proposition ?

Bonjour JFL

Désolée de ne pas avoir pu répondre à votre réponse, j ai appliqué la fonction que vous m'avez proposé mais ca n a pas marcher. Merci pour ton temps c est vraiment gentille de votre part

Merci à vous tous

Bonjour à tous,

Une proposition amendée pour Excel 365.

=BYROW(A1:A60;LAMBDA(r;MIN(4;ENT(JOUR(r)/7)+1)))

Le numéro de la semaine est limité à....4 selon votre souhait. Cela peut conduire à des semaines de 10 jours. J'ai connu l'époque des "4 jeudis". Maintenant, et grâce à vous, c'est la semaine décadaire.

Bonjour

C'est vrai je n ai pas pensé à ca .Merci beaucoup JFL

Cordialement