Export Excel vers pdf

Bonjour,

quelqu'un pourrait-il me dire le code VBA à insérer afin que le résultat de l'export en PDF reste concentré sur une page.

ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _
Filename:=chemin & nom_fichier, _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
from:=1, To:=1, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=True

merci pour votre aide.

Bonjour

je ne sait pas si ca peu vous aider, mais il faut adapter a votre guise

With Worksheets("DEVIS")
    ' Outils pour ouvrir une boite de dialogue et choisir l'emplacement voulu :
    With Application.FileDialog(msoFileDialogFolderPicker)
        If .Show = -1 Then
            Chemin = .SelectedItems(1) & "\"
        End If
    End With
    ' Sauvegarde au format pdf
     ' (avec ajout de la variable "chemin" dans Filename, mais le chemin de destination ne se mettra pas dans le nom du fichier)
    Fichier = "Devis n° " & .Range("F8") & .Range("G8") & .Range("H8") & ".pdf"

    .ExportAsFixedFormat Type:=xlTypePDF, FileName:= _
                                Chemin & Fichier, _
                                Quality:=xlQualityStandard, _
                                IncludeDocProperties:=True, _
                                IgnorePrintAreas:=False, _
                                OpenAfterPublish:=True

End With

Bonsoir,

merci pour cette réponse mais cela ne m'aide pas car l'export se passe très bien MAIS, il faudrait que l'export de la feuille excel se fasse à échelle réduite de façon à obtenir un fichier PDF d'une seule page.

Bonsoir gouyasse, ilies, le forum,

il faudrait que l'export de la feuille excel se fasse à échelle réduite de façon à obtenir un fichier PDF d'une seule page.

à tester...

With Worksheets("Ta_Feuille") ' à adpater
    .PageSetup.Zoom = False
    .PageSetup.FitToPagesTall = 1
    .PageSetup.FitToPagesWide = 1

    .ExportAsFixedFormat Type:=xlTypePDF, _
     Filename:=chemin & nom_fichier, _
     Quality:=xlQualityStandard, _
     IncludeDocProperties:=True, _
     from:=1, To:=1, _
     IgnorePrintAreas:=False, _
     OpenAfterPublish:=True
 End With

Cordialement,

Cela ne donne pas le résultat attendu car en fonction des circonstances, les données de la feuille excel "débordent" sur la pager suivante de sorte que lorsque je sauvegarde en PDF, toutes les colonnes de la page 2 viennent s'ajouter et compriment les données de la page 1. Ce qui pour une facture n'est pas acceptable.

Bref en lieu et place de la page j'ai plutôt travaillé sur la plage de cellules et là le résultat est impeccable avec ou sans "débordement".

Pour ceux que cela pourrait intéresser voici ma (très) modeste contribution.

With ActiveSheet 'sauvegarde au format PDF

Range("A2:G52").Select
.PageSetup.Zoom = False
.PageSetup.FitToPagesTall = 1
.PageSetup.FitToPagesWide = 1

Selection.ExportAsFixedFormat Type:=xlTypePDF, _
Filename:=chemin & nom_fichier, _
Quality:=xlQualityStandard, _
IncludeDocProperties:=True, _
from:=1, To:=1, _
IgnorePrintAreas:=False, _
OpenAfterPublish:=True

End With

Bonjour,

Tu peux peut-être remplacer:

Range("A2:G52").Select

par

 .PageSetup.PrintArea = "$A$2:$G$52"

A tester....

 With ActiveSheet
    .PageSetup.PrintArea = "$A$2:$G$52"
    .PageSetup.Zoom = False
    .PageSetup.FitToPagesTall = 1
    .PageSetup.FitToPagesWide = 1

    .ExportAsFixedFormat Type:=xlTypePDF, _
     Filename:=chemin & nom_fichier, _
     Quality:=xlQualityStandard, _
     IncludeDocProperties:=True, _
     from:=1, To:=1, _
     IgnorePrintAreas:=False, _
     OpenAfterPublish:=True
 End With

Cordialement,

Merci pour la réaction mais où se trouve l'amélioration.

je suis curieux car ma maîtrise VBA reste limitée

Re,

Merci pour la réaction mais où se trouve l'amélioration.

On évite une sélection inutile.

Vu que dans le code, on utilise les paramètres de la feuille, on rajoute simplement le paramètre "zone d'impression".

Dans ton cas, ce n'est pas perceptible, mais si tu abuses des select, tu constateras que cela ralenti l'exécution du code, je ne fait qu'appliquer les conseils des pros (éviter les select et activate tant que possible) ,

Cordialement,

C'est vrai que je constate parfois un ralentissement du code et je sais que je suis bon utilisateur des "Select".

Je vais regarder à cela mais entretemps, voilà une réponse comme je les aime. Claire, nette et précise.

Merci !!