Extraire des nombres entre parenthèse dans une cellule alphanumérique

Bonjour à tous,

Dans une liste de titres de films, je souhaiterai extraire une date (année) qui se trouve entre parenthèse, dans une cellule qui contient potentiellement une autre parenthèse avec des lettres :

Ex: J'ai une cellule (A2) qui contient un texte du genre : "Alien 3 (version longue) - 1080p MULTI (1992).mkv"

je souhaiterai extraire la date "1992" (qui en plus de toujours être en parenthèse, est toujours la dernière chaine de caractère avant .mkv ou .mp4 ou .avi)

En fouillant sur google et sur ce forum, j'ai trouvé la formule : =STXT(A2;TROUVE("(";A2)+1;(TROUVE(")";A2)-TROUVE("(";A2))-1)
qui fonctionne parfaitement dans les cellules où il n'y a qu'une seule parenthèse, mais pas dans le cas ci-dessous ou une autre parenthèse précède.

J'ai essayé de chipoter avec DROITE, avec TROUVE, avec CNUM, mais n'étant pas du tout un expert, je n'ai pas réussi à trouver la solution, que j'aimerai sans macro/vba/matriciel

D'avance merci à tous pour votre aide :)

Bonjour,

Peut-être peux-tu essayer ceci ?

=SI(NBCAR(A2)-NBCAR(SUBSTITUE(A2;"(";""))=1;STXT(A2;TROUVE("(";A2)+1;(TROUVE(")";A2)-TROUVE("(";A2))-1);STXT(A2;TROUVE("(";SUBSTITUE(A2;"(";"";1))+2;4))

Cela suppose que la date est toujours écrite sur 4 caractères. Comme tu n'as pas donné tous les cas, je ne sais pas si c'est toujours ainsi ou pas.

C'est le cas, toujours seulement l'année en 4 chiffres, du coup ça fonctionne parfaitement !

Merci infiniment !

Super, merci pour le retour.

bonjour

une contribution

cordialement

Bonjour la Tulipe !

Ça fait plaisir de revoir des tridactyles en ton genre dans le coin !

Solution brillante ! L'évaluation de la formule est de toute beauté. Bon, c'est de la triche puisqu'on voulait sans matricielle, mais c'est beau ;)

Bonjour à tous,

Courte contribution

je souhaiterai extraire la date "1992" (qui en plus de toujours être en parenthèse, est toujours la dernière chaine de caractère avant .mkv ou .mp4 ou .avi)

=DROITE(GAUCHE(G4;NBCAR(G4)-5);4)

et meme

=STXT(G4;NBCAR(G4)-9.4)

D'un autre coté pourquoi faire simple quand on ..........

Crdlmt

Droite gauche droite gauche...

J'avais pensé à un même genre de formule aussi...

Bonjour,

Oui en effet c'est tentant.

Si c'est un fichier vidéo Mp4, ça fonctionne, si c'est du Mkv, ça fonctionne, si c'est du Mpeg, ça plante. Je suis également parti du principe que le titre peut contenir un point et qu'on ne pouvait pas se baser dessus pour la recherche.

Bonjour à tous !

Et peut-être que :

=GAUCHE(DROITE(B14;9);4)

EDIT : ou (pour tenir compte de la remarque de JoyeuxNoel) :

=DROITE(GAUCHE(B14;TROUVE(".";B14)-2);4)

EDIT 2 : Arf..... le "." dans le titre.....

Bonsoir à tous,

Si c'est

toujours la dernière chaine de caractère avant .mkv ou .mp4 ou .avi

Alors, même si Mpeg

=STXT(A2;TROUVE(")";A2;NBCAR(A2)-5)-4;4)

devrait convenir.

Bonsoir à tous !

Une dernière :

=STXT(B3;TROUVE(").";B3)-4;4)

Bonsoir,

Bravo X Cellus et JFL, vous avez bien raccourci là 😁

Waw, merci à tous pour vos contributions !

Autant de solutions à un problème, vous avez été efficaces ! Merci