Listbox pour selectionner plages nommées

Question

J’utilise une macro qui marche très bien pour faire appel à une plage nommée A l’aide choix combobox sur userform selon le mois courant écris manuellement dans la colonne « L » Ce que je cherche c’est le même objectif de ma macro mais remplacer le combobox par une listebox avec des cases à coché suivi des noms des plages et quand : On coche = plage sélectionnée On décoche = plage désélectionnée J'espère avoir été clair. Je vous joins le fichier test (simplifié pour cette discussion) Merci d’avance Cordialement...

3GB · Answer

Pourquoi voulez-vous sélectionner des plages ? Cdlt...

ThauThème · Answer

Bonjour le fil, bonjour le forum,

Essai comme ça :

Option Explicit
Private O As Worksheet

Private Sub UserForm_Initialize()
Set O = Worksheets("Feuil1")
O.Range("A1").Select
ListBox1.List() = O.Range("A1:A4").Value
With ListBox1
    .MultiSelect = 1
    .ListStyle = 1
End With
End Sub

Private Sub ListBox1_Change()
Dim I As Byte
Dim PL As Range
Dim TEST As Boolean

Set PL = O.Range("A1")
For I = 0 To Me.ListBox1.ListCount - 1
    If Me.ListBox1.Selected(I) = True Then
        Set PL = IIf(PL.Cells.Count = 1, O.Range(Me.ListBox1.List(I)), Application.Union(PL, O.Range(Me.ListBox1.List(I))))
        TEST = True
        PL.Select
    End If
Next I
If TEST = False Then O.Range("A1").Select
End Sub

Private Sub CheckBox1_click()
Dim I As Byte

If CheckBox1.Value = True Then
    O.Range("ZEF_1, ZEF_2, ZEF_3, ZEF_4").Select
    For I = 0 To Me.ListBox1.ListCount - 1
        Me.ListBox1.Selected(I) = True
    Next I
Else
    O.Range("A1").Select
    For I = 0 To Me.ListBox1.ListCount - 1
        Me.ListBox1.Selected(I) = False
    Next I
End If
End Sub

Private Sub CommandButton2_Click()
Dim Reponse As Integer

Reponse = MsgBox("Veux-tu remettre à blanc le contenu du tableau ?", vbYesNo + vbExclamation, "Effacer")
If Reponse = vbYes Then Selection.ClearContents
End Sub

Private Sub CommandButton1_Click()
O.Range("A1").Select
Unload UF_Lbx
End Sub

jiba · Answer

Premièrement désolé 3GB de ne pas répondre a ta question car j'avais constamment un problème d'accès à mon compte (Erreur mot de passe) alors je l'ai supprimer puis recréer. Merci 3GB et grand merci à TauThem pour le temps qu'a consacrai pour la bonne solution à ma question ça marche très bien. je vais avancer avec ta solution sur le fichier...