Supprimer ligne / conditions / VBA

Bonjour à tous,

J'espère que vous allez tous bien !

Je vous écris car je bloque pour établir une suppression de ligne(s) Excel avec VBA.

Je vous joins mon fichier pour que cela soit plus clair !

En gros, des lignes doivent se supprimer en fonction de conditions définies dans une autre de feuille de calcul, en VBA.

Pour que cela soit bien clair, je vous ai mis le résultat attendu dans une autre feuille.

Je galère vraiment!!

Merci beaucoup pour votre aide.

Fifou

Bonsoir fifou6901, le forum,

Un essai....

Option Explicit

Dim tablo, tabloR()
Dim i&, j&, k&, dl%, lig%
Dim sh As Worksheet

Sub test()
    tablo = Sheets("Etat").Range("A1").CurrentRegion
    Set sh = Sheets("Condition")
    dl = sh.Range("a" & Rows.Count).End(xlUp).Row

    k = 0
    For i = 2 To UBound(tablo, 1)
     For lig = 2 To dl
      If tablo(i, 3) = sh.Range("A" & lig) And tablo(i, 11) >= sh.Range("B" & lig) Then
       ReDim Preserve tabloR(1 To 12, 1 To k + 1)
        For j = 1 To 12
         tabloR(j, 1 + k) = tablo(i, j)
        Next j
       k = 1 + k
      End If
     Next lig
    Next i

   With Sheets("Resultat")
    .Range("A1").CurrentRegion.Offset(1, 0).ClearContents
    On Error Resume Next
    .Range("A2").Resize(UBound(tabloR, 2), 12) = Application.Transpose(tabloR)
    .Activate
   End With
End Sub

Cordialement,

Bonjour à tous

Essaie cela :

Sub Suppr()
Dim WE, WC As Worksheet
Set WE = Sheets("Etat")
Set WC = Sheets("Condition")

DLig = WE.Range("A65536").End(xlUp).Row
For k = DLig To 2 Step -1
    CompteRech = WE.Cells(k, 3)
    Set Trouve = WC.Cells.Find(what:=CompteRech, LookAt:=xlWhole)
    If Trouve Is Nothing Then
        MsgBox "Pb non trouvé"
        Exit Sub
    Else
        lig = Trouve.Row
        If WE.Cells(k, 11) < WC.Cells(lig, 2) Then
            'A supprimer
            WE.Rows(k).EntireRow.Delete
        End If
    End If
Next
End Sub

Bonne soirée

Bonjour

Bonjour à tous

Une variante...

Bye !

Merci à vous trois pour vos retours rapides!!

Vos propositions marchent parfaitement!

Je ne connaissais pas du tout la méthode cells.find donc je vais parfaire tout cela!

Encore merci et bonne fin de weekend,

Fifou