Problème avec VLOOKUP

Bonjour

je cherche a calculer une somme en utilisant la fonction VLOOKUP

c a d : je cherche dans ma 1ere colonne jusq a trouvé PB2 et sommer sur colonne 7.

j'utilise l code suivant mais il somme que sur la 1ére ligne trouvée :

Private Sub CommandButton1_Click()
Dim s As Single
'DerL = Range("A" & Rows.Count).End(xlUp).Row
DerL = Feuil4.Range("A" & Rows.Count).End(xlUp).Row
s = 0
For i = 3 To DerL
If Feuil4.Cells(i, 1) = "Pb2" Then
s = s + Application.VLookup(Feuil4.Range("A" & i), Feuil4.Range("A:W"), 7, False)
End If
Next i
MsgBox s
End Sub

merci pour votre aide

Bonjour,

l'utilisation de VLOOKUP est-elle obligatoire ?

Si non, c'est plus simple.

A+

Bonjour Hemed, AlgoPlus, le forum,

Peut-être ainsi....

Sub test()
 Dim s, DerL, i
 Dim plage As Range

  With Sheets("départ")
   DerL = .Range("A" & Rows.Count).End(xlUp).Row
      s = 0
       For i = 3 To DerL
        Set plage = .Range("A" & i & ":W" & DerL)
         If .Cells(i, 1) = "pb2" Then
            s = s + Application.VLookup(.Cells(i, 1), plage, 7, False)
         End If
       Next i
  End With
    MsgBox s
End Sub

CTRL + E pour exécuter la macro

Une variante avec Somme.Si

Sub test()
 Dim s, DerL
 Dim plagecritere As Range, plageresultat As Range

  With Sheets("départ")
   DerL = .Range("A" & Rows.Count).End(xlUp).Row
   Set plagecritere = .Range("A3:A" & DerL)
   Set plageresultat = .Range("G3:G" & DerL)
    s = Application.WorksheetFunction.SumIf(plagecritere, "pb2", plageresultat)
  End With
    MsgBox s
End Sub

Cordialement,

Bonjour xorsankukai,

Ce à quoi je pensais :

Dim s As Single
With Sheets("départ")
 For i = 3 To .Range("A" & Rows.Count).End(xlUp).Row
    If .Cells(i, 1) = "pb2" Then s = s + .Range("G" & i)
 Next i
End With
MsgBox s

A+

Re,

Effectivement, c'est bien plus simple ainsi, bien vu,

Amicalement,

merci beaucoup xorsankukai,

Re,

merci beaucoup xorsankukai,

Merci pour ton retour,

N'oublies pas notre ami AlgoPlus qui t'as également proposé une solution ,

Cordialement,