Ordre sans vide sans VBA

Bonjour

question pour celui qui peu m'aider, pour un ordre sans VBA

je presente mon problème

j'ai une colonne "A" remplis de prénom, décalé par des lignes vide et le vide et aléatoire

pourrais-je les classer dans la colonne "D" ( ou autres colonne) dans les vides avec formules???

je joint un fichier modèle

merci d'avance

Bonjour iliyes,

Moi j'aurais fait un TCD en décochant (vide) puis un tri...

Ou en passant par Power Query, c'est aussi possible.

merci pour l'idée, j'y avais pensé, mais c'est pas possible dans le fichier originale

en formule !!! si c'est possible

Salut,

T'as dit une formule

En voilà une, que R@chid avait fait. Elle est en matricielle et elle tri par ordre alphabétique.

Pour la beauté de la rédaction, je la pose là

{=SIERREUR(INDEX(A2:A20;MOD(PETITE.VALEUR(SI(PETITE.VALEUR(SI(A2:A20<>"";(NB.SI(A2:A20;"<"&A2:A20)+1));LIGNE(INDIRECT("1:"&NBVAL(A2:A20))))=LIGNE(INDIRECT("1:"&NBVAL(A2:A20)));PETITE.VALEUR(SI(A2:A20<>"";NB.SI(A2:A20;"<"&A2:A20)*10^5+LIGNE(INDIRECT("1:"&LIGNES(A2:A20))));LIGNE(INDIRECT("1:"&NBVAL(A2:A20)))));LIGNE(INDIRECT("1:"&NBVAL(A2:A20))));10^5);MOD(MOD(PETITE.VALEUR(SI(PETITE.VALEUR(SI(A2:A20<>"";(NB.SI(A2:A20;"<"&A2:A20)+1));LIGNE(INDIRECT("1:"&NBVAL(A2:A20))))=LIGNE(INDIRECT("1:"&NBVAL(A2:A20)));PETITE.VALEUR(SI(A2:A20<>"";NB.SI(A2:A20;"<"&A2:A20)*10^5+LIGNE(A2:A20)*10^2+COLONNE(A2:A20)-COLONNE(A:A)+1);LIGNE(INDIRECT("1:"&NBVAL(A2:A20)))));LIGNE(INDIRECT("1:"&NBVAL(A2:A20))));10^5);10^2));"")}

Tu l'a mets sur ton fichier, tu changes la plage avec "remplacer" du ruban et tu la valides par Ctrl+Alt+Entrée

Sinon

avec la fonction UNIQUE

=UNIQUE(A2:A20;FAUX;VRAI)

Beaucoup moins de charme et qui ne tri pas

Leakim

Bonjour,
Une autre formulation sans tri.
Pour Excel 2019+
Cdlt.

=FILTRE.XML("<t><s>" & SUBSTITUE(JOINDRE.TEXTE(";"; 1; A2:A20); ";"; "</s><s>") & "</s></t>"; "//s")

Bonjour à tous !

Pour parfaire la diversité, une autre approche ?

=INDEX(A2:A20;PETITE.VALEUR(SIERREUR(EQUIV(A2:A20;A2:A20;0);"");LIGNE(INDIRECT("1:"&NBVAL(A2:A20)))))

Bonjour,

dans la rubrique Excel VBA il manquerait plus que ce soit sans VBA et sans Excel

Salut,

T'as dit une formule

En voilà une, que R@chid avait fait. Elle est en matricielle et elle tri par ordre alphabétique.

Pour la beauté de la rédaction, je la pose là

{=SIERREUR(INDEX(A2:A20;MOD(PETITE.VALEUR(SI(PETITE.VALEUR(SI(A2:A20<>"";(NB.SI(A2:A20;"<"&A2:A20)+1));LIGNE(INDIRECT("1:"&NBVAL(A2:A20))))=LIGNE(INDIRECT("1:"&NBVAL(A2:A20)));PETITE.VALEUR(SI(A2:A20<>"";NB.SI(A2:A20;"<"&A2:A20)*10^5+LIGNE(INDIRECT("1:"&LIGNES(A2:A20))));LIGNE(INDIRECT("1:"&NBVAL(A2:A20)))));LIGNE(INDIRECT("1:"&NBVAL(A2:A20))));10^5);MOD(MOD(PETITE.VALEUR(SI(PETITE.VALEUR(SI(A2:A20<>"";(NB.SI(A2:A20;"<"&A2:A20)+1));LIGNE(INDIRECT("1:"&NBVAL(A2:A20))))=LIGNE(INDIRECT("1:"&NBVAL(A2:A20)));PETITE.VALEUR(SI(A2:A20<>"";NB.SI(A2:A20;"<"&A2:A20)*10^5+LIGNE(A2:A20)*10^2+COLONNE(A2:A20)-COLONNE(A:A)+1);LIGNE(INDIRECT("1:"&NBVAL(A2:A20)))));LIGNE(INDIRECT("1:"&NBVAL(A2:A20))));10^5);10^2));"")}

Tu l'a mets sur ton fichier, tu changes la plage avec "remplacer" du ruban et tu la valides par Ctrl+Alt+Entrée

Sinon

avec la fonction UNIQUE

=UNIQUE(A2:A20;FAUX;VRAI)

Beaucoup moins de charme et qui ne tri pas

Leakim

merci LEAKIM, unique fonctionne bien, mais pas sur les date, mais je prend quand meme

Bonjour,
Une autre formulation sans tri.
Pour Excel 2019+
Cdlt.

=FILTRE.XML("<t><s>" & SUBSTITUE(JOINDRE.TEXTE(";"; 1; A2:A20); ";"; "</s><s>") & "</s></t>"; "//s")

Bonjour

ca fonctionne très très bien, merci

Bonsoir à tous !

...... unique fonctionne bien ......

La fonction UNIQUE dans un environnement 2016/2019 ?

bonsoir

une contribution

matricielle (bouchage des trous)

SIERREUR(INDEX(A$2:A$20;PETITE.VALEUR(SI(A$2:A$20<>"";LIGNE(A$2:A$20)-1;"");LIGNE(A1)));"")

sans validation tridactyle

SIERREUR(INDEX(A$2:A$20;SOMMEPROD(PETITE.VALEUR((A$2:A$20<>"")*(LIGNE(A$2:A$20));NB.SI(A$2:A$20;"")+LIGNE(A1))-1));"")

par ordre alpha (au cazou)

SIERREUR(INDEX(A$2:A$20;EQUIV(PETITE.VALEUR(SI(A$2:A$20<>"";NB.SI(A$2:A$20;"<"&A$2:A$20);"");LIGNE(A1));SI(A$2:A$20<>"";NB.SI(A$2:A$20;"<"&A$2:A$20);"");0));"")

cordialement

Rechercher des sujets similaires à "ordre vide vba"