Comptabiliser lignes pleines et lignes vides

Bonjour à tous,

Dans mon tableau, il y’a des lignes pleines et d’autres sont vides.

J’aimerais trouver un moyen pour trouver le nombre des lignes pleines et mettre ce nombre dans la cellule K1, et puis trouver également le nombre de lignes vides et le mettre dans la cellule M1.

Le nombre de lignes vides à rechercher concerne seulement les lignes qui se trouvent parmi les lignes pleines, ceux qui se trouvent après la dernière ligne pleine ne doivent être comptabilisées.

la première ligne (l'entête) est figée et ne doit pas être comptabilisée.

Merci pour votre aide.

Bonjour Harzer, bonjour le forum,

C'est quoi le critère pour qu'une ligne soit pleine ???

• Toutes les cellules de la ligne sont renseignées
• Au moins une cellule de la ligne est renseignée
• autre

Re,

Si ton critère est : au moins une cellule de la ligne est renseignée, le code ci-dessous devrait convenir :

Sub Macro()
Dim O As Worksheet 'déclare la variable O (Onglet)
Dim DL As Integer 'déclare la variable DL (Dernière Ligne)
Dim TC As Variant 'déclare la variable TC (tableau de Cellules)
Dim NL As Integer 'déclare la variable NL (Nombre de Lignes)
Dim NC As Byte 'déclare la variable NC (Nombre de Colonnes)
Dim LV As Integer 'déclare la variable LV (Lignes Vides)
Dim LP As Integer 'déclare la variable LP (Lignes Pleines)
Dim TEST As Boolean 'déclare la variable TEST

Set O = Sheets("Feuil1") 'définit l'onglet O
DL = O.Cells(Application.Rows.Count, 1).End(xlUp).Row 'définit la dernière ligne éditée DL de la colonne 1 (=A) de l'onglet O
TC = O.Range("A1:I" & DL) 'définit le tableau de cellules TC
NL = UBound(TC, 1) 'définit le nombre de lignes du tableau de cellules TC
NC = UBound(TC, 2) 'définit le nombre de colonnes du tableau de cellules TC
For I = 2 To NL 'boucle 1 : sur toutes les lignes de TC (en partant de la seconde)
    TEST = False 'réinitialise la variable TEST
    For J = 1 To NC 'boucle 2 : sur toutes les colonnes de TC
        If TC(I, J) <> "" Then 'condition : si la valeur ligne I colonne J n'est pas vide
            TEST = True 'définit la variable TEST
            Exit For 'sort de la boucle
        End If 'fin de la condition
    Next J 'prochaine colonne de la boucle 2
    'si test est [Faux] incrémente le nombre de ligne vide LV, si TEST est [Vrai] incrémente le nombre de ligne pleines LP
    If TEST = False Then LV = LV + 1 Else LP = LP + 1
Next I 'prochaine ligne de la boucle 1
O.Range("K1").Value = LP 'renvoie le nombre de lignes pleines LP dans la cellule K1 de l'onglet O
O.Range("M1").Value = LV 'renvoie le nombre de lignes vides LV dans la cellule M1 de l'onglet O
End Sub

bonjour

sans vba

cordialement

Re,

Pfff Tulipe ! Même pas mal...

(je le hais, je le hais, je le hais... parce qu'il est trop fort !)

Bonjour ThauThème et tulipe_4,

Tout d’abord, merci de me répondre.

En effet ThauThème, dans mon cas, une ligne est pleine si au moins une cellule est renseignée.

Le code que vous me proposer répond totalement à mes attentes, merci.

Merci également à tulipe_4, les formules proposées donnent également le résultat désiré.

Cordiale poignée de main à tous les deux.

re

pas d'emballement parce je crois que me suis planté sur les reelement pleines ( c.a.d 9 valeurs)

je cherche (pour le fun) ;mais ce n'est pas de la tarte pour l'avoir en direct sans col (masquable)

cordialement