Aide sur formule Excel
J'ai besoin de votre aide afin de rédiger une formule qui me fera gagner beaucoup de temps.
Cela fait trois jours que j'essais mais je n'y arrive pas.
Voici mon problème:
La cellule A1 contient du texte exemple "pommes,raisin,cerises"
La cellule A3 contient une valeur variable.
Ce que je recherche est que lorsque le texte UNIQUEMENT "pommes" contenu en A1 est trouvé
alors afficher en A2 la valeur de A3.
J'utilise excel 2000
Je vous remercie pour votre aide.
Cordialement
Jean
Veuillez m'excuser du précédent post, mais j'ai oublié de vous donner un exemple.
J'ai besoin de votre aide afin de rédiger une formule qui me fera gagner beaucoup de temps.
Cela fait trois jours que j'essais mais je n'y arrive pas.
Voici mon problème:
La cellule A1 contient du texte exemple "pommes raisin cerises"
La cellule A3 contient une valeur variable.
Ce que je recherche est que lorsque le texte UNIQUEMENT "pommes" contenu en A1 est trouvé
alors afficher en A2 la valeur de A3.
Exemple de formule dans A2:
=SI(A1="pommes raisin cerises";A3;0) cette formule fonctionne bien.
Par contre celle qui m'intéresse et qui ne fonctionne pas est la suivante:
=SI(A1="pommes";A3;0)
J'utilise excel 2000
Je vous remercie pour votre aide.
Cordialement
Jean
Bonjour,
Un petit exemple en VBA
https://www.excel-pratique.com/~files/doc/655_Chercher_mot.xls
Cordialement
Alain
Bonjour,
Par formule :
=ESTNUM(TROUVE("pommes";A1))*A3
Cette formule "simple" a bien l'inconvénient de renvoyer la valeur de A3 si une partie de la valeur cherchée est trouvée, par exemple "pomme" ou "pom".
La formule suivante ne renvoie la valeur de A3 que si la valeur exacte est trouvée :
=ESTNUM(TROUVE(" pommes ";" "&A1&" "))*A3
C'est à dire rechercher la valeur, espaces compris, en ajoutant des espaces avant et après A1.
dré
Bonjour,
J'ai vu la copie du même post ailleurs avec une réponse.
Espérons que tu donneras réponse là aussi.
A bientôt
Dan
Parfait ça marche ! c'est super.
Ces deux formules fonctionnent à merveille c'est ce que je recherchais.
=ESTNUM(TROUVE("pommes";A1))*A3
=ESTNUM(TROUVE(" pommes ";" "&A1&" "))*A3
Par contre ce que j'aimerais aussi,afin que la valeur de A3 s'affiche en A2, est que le texte
trouvé dans la cellule A1 soit "pommes" OU BIEN "cerises". Cela me servira pour une autre
application.
En attendant un grand merci pour votre aide.
Ce forum est génial.
Cordialement
Jean
Bonjour,
Voici ce que je propose :
=SI(OU(ESTNUM(TROUVE(" pommes ";" "&A1&" "));ESTNUM(TROUVE(" cerises ";" "&A1&" ")));A3;0)
@+
Matthieu
Toutes les formules que l'on m'a communiquées fonctionnent parfaitement.
Je n'ai maintenant que l'embarras du choix ! ! !
Vraiment super ce forum.
Un grand merci à tous pour votre aide.
Cordialement
Jean
Bonjour,
Petite variante :
=MAX(ESTNUM(TROUVE(" pommes ";" "&A1&" "));ESTNUM(TROUVE(" cerises ";" "&A1&" ")))*A3
Autre possibilité, un peu plus court :
=((NBCAR(A1)-NBCAR(SUBSTITUE(SUBSTITUE(A1;"poires";"");"cerises";"")))>0)*A3
dré
Merci pour ce supplément de formule.
Je ne pensais pas qu'il y avait autant de formules différentes pour arriver au
même résultat.
Merci à tous. Très sympa de m'avoir aidé.
Cordialement
Jean
Bonjour à tous,
Ma petite contribution :
En inscrivant le mot recherché en B1 (par exemple), la formule devient :
=ESTNUM(TROUVE(B1;A1))*A3
Plus besoin de prévoir une formule à rallonge incluant tous les mots recherchés.
Amicalement
Nad
Ce système est très intéressant. Je vais le tester.
Merci
Cordialement
Jean