Dupliquer code pour colonne suivante

Bonjour,

sur ma feuille, en colonne D, si on clique sur une cellule, le chiffre"0" apparait.

Je souhaiterais qu'en colonne E, si on clique sur une cellule, le chiffre "1" apparaisse.

Comment dois-je faire?

Merci beaucoup

Code :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

If Not Intersect(Range("D5:D91"), Target) Is Nothing And Target.Count = 1 Then

Application.EnableEvents = False:

If Target = "" Then

Target = "0"

Else

Target = ""

End If

Application.EnableEvents = True

End If

End Sub

Bonsoir keavero, le fil,

Je souhaiterais qu'en colonne E, si on clique sur une cellule, le chiffre "1" apparaisse.

Toujours de la ligne 5 à la ligne 91 ?

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

If Not Intersect(Range("D5:D91"), Target) Is Nothing And Target.Count = 1 Then
       Application.EnableEvents = False:
If Target = "" Then
   Target = "0"
Else
   Target = ""
End If
End If

If Not Intersect(Range("E5:E91"), Target) Is Nothing And Target.Count = 1 Then
If Target = "" Then
   Target = "1"
Else
   Target = ""
End If
End If

       Application.EnableEvents = True
End Sub

Cordialement,

Vraiment merci beaucoup, c'est tout à fait ce que je cherchais.

Bonne soirée.

Bonsoir keavero, xorsankukai,

je propose cette optimisation du code VBA de xorsankukai :

Option Explicit

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
  Dim k As Byte
  With Target
    If .CountLarge > 1 Then Exit Sub
    If Not Intersect(Target, [D5:D91]) Is Nothing Then k = 1
    If Not Intersect(Target, [E5:E91]) Is Nothing Then k = 2
    If k = 0 Then Exit Sub
    Application.EnableEvents = False
    If .Value = "" Then .Value = k - 1 Else .ClearContents
    Application.EnableEvents = True
  End With
End Sub

dhany

Bonjour,

Si on doit optimiser :

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    If Target.CountLarge = 1 Then
        If Not Intersect(Target, Range("D5:E91")) Is Nothing Then
            Select Case Target.Column
                Case 4: Target.Value = IIf(IsEmpty(Target), 0, Empty)
                Case 5: Target.Value = IIf(IsEmpty(Target), 1, Empty)
            End Select
        End If
    End If
End Sub

Sans information complémentaire EnableEvents est inutile dans la procédure.

Cdlt.