Affichage d'un tableau sur une colonne

Bonjour,

J'ai un tableau comme ci-dessous.

Ce tableau est complété régulièrement en fonction de l'évolution du tarif des professeurs.

J'aimerais pouvoir l'afficher sous la forme d'une colonne comme ci-desous pour pouvoir faire une recherche de valeur.

prof 1 tarif 1

prof 1 tarif 2

prof 2 tarif 3

prof 3 tarif 4

prof 3 tarif 5

prof 3 tarif 6

Sauriez-vous m'aider à le faire?

Merci d'avance

et sans les dates ?

ce serait mieux d'avoir des données qui ne sont pas en image, cela éviterait de recopier à la main

=query(arrayformula(split(flatten(A1:A&"~"&B1:G);"~";1;0));"where Col1 is not null and Col2 is not null")

Ca fonctionne. Super.

J'aurais besoin d'une petite complexité supplémentaire.

Est-ce qu'il serait possible de ne filtrer que les derniers tarifs.

Pour le tableau que tu as créé, le résultat donnerait:

prof1 tarif2

prof2 tarif3

prof3 tarif8

peux-tu donner un tableau recopiable de données (j'ai effacé mon propre jeu de données et c'est un peu long de le recréer)

Est-ce que ça conviendrait comme ça?

c'est parfait !

je vais continuer à chercher une solution complètement intégrée

pour le moment, en 2 étapes

1- recherche colonne max par ligne, en H1

version US
=query(query(arrayformula(split(flatten(A1:A&"~"&B1:G&"~"&column(B1:G1)),"~",1,0)),"where Col1 is not null and Col2 is not null"),"select Col1,max(Col3) group by Col1 label max(Col3) ''")

version FR
=query(query(arrayformula(split(flatten(A1:A&"~"&B1:G&"~"&column(B1:G1));"~";1;0));"where Col1 is not null and Col2 is not null");"select Col1,max(Col3) group by Col1 label max(Col3) ''")

2- recherche de la valeur, en K1, formule à tirer vers le bas

version US     =offset($A$1,match(H1,A:A,0)-1,I1-1)
version FR     =offset($A$1;match(H1;A:A;0)-1;I1-1)

Ca marche très bien. Super.

Par contre, mon tableau ne commence pas en A1 mais en D2 et lorsque j'adapte la formule pour tenir compte de ce décalage, la formule "decaler" ne fonctionne pas. Aucun résultat ne s'affiche.

Pourquoi?

=DECALER($D$2;EQUIV(T2;D$2:D;0)-1;U2-1)

Ca y est j'ai trouvé.
C'est le décalage des colonnes qui ne fonctionnait pas.
Merci encore

une meilleure réponse, (elle n'est pas de moi)

version US
=INDEX(regexextract(trim(transpose(query(transpose(filter(A:F, len(A:A))),,9^9))), "^(.*?)\s.*?([^\s]+$)"))

version FR
=INDEX(regexextract(trim(transpose(query(transpose(filter(A:F; len(A:A)));;9^9))); "^(.*?)\s.*?([^\s]+$)"))

pfiou. Je suis incapable de comprendre cette formule. Ca peut marcher en mettant un "arrayformula"?

oui à la place de index

je t'avoue que je suis en train de la décoder ... elle n'est pas de moi en effet mais de quelqu'un que j'ai sollicité

j'avais bien essayé le query(transpose(___);______;9^9) qui permet de concaténer des colonnes, mais je n'avais pas été jusqu'au bout

maintenant c'est du travail d'épluchage de l'oignon pour comprendre